Перейти к основному содержимому

Переменные

Переменная — это ссылка на область памяти, которая хранит значение какого-либо типа. Для идентификации переменной служит имя переменной, которое указывается после специального модификатора. На имя переменной накладываются ограничения в соответствии с правилами формирования имен.

Значение каждой переменной имеет конкретный тип. Переменные можно использовать только внутри тела метода после их инициализации (присваивания значения), при этом тип данных переменной определяется автоматически. Тип данных переменной необходимо обязательно указывать в случае ее объявления без инициализации.

Переменная может быть простого или составного типа. В первом случае в переменной должно быть значение того типа, который указан при ее объявлении (и все потомки этого типа). Если для переменной указан составной тип данных, то это означает, что переменная может принимать значения нескольких типов, указанных при объявлении переменной. Любая попытка присвоить переменной значение, тип которого не соответствует типу (или типам) объявления переменной, будет вызывать ошибку.

метод ПолучитьИнформациюОФайле(): Строка
    // Переменная составного типа без инициализации
    пер ТекстовыйФайл: Файл?
    
    // Переменная простого типа с инициализацией
    знч Путь = "C:\\test\\file.txt"
    
    // Переменная простого типа без инициализации
    пер Размер: Число
    
    // В переменную типа Объект присваивается наследник — тип Строка
    знч Система: Объект = СредаИсполнения.ПолучитьПеременную("OS")
    
    // Инициализация переменной ТекстовыйФайл
    ТекстовыйФайл = новый Файл(Путь)
    
    если ТекстовыйФайл != Неопределено и ТекстовыйФайл.Существует()
        знч Имя = ТекстовыйФайл.Имя
        Размер = ТекстовыйФайл.Размер // Несовместимые типы: РазмерБайтов не может быть присвоен в Число
        Размер = ТекстовыйФайл.Размер.ВБайтах()
        
        возврат "Файл: $Имя, Путь: $Путь, Размер: $Размер, ОС: $Система"
    иначе
        возврат "Файл не найден"
    ;
;

Имена переменных​

Имя переменной — это идентификатор, расположенный после модификатора вида переменной, по которому происходит обращение к хранимому в ней значению.

Имя переменной может начинаться с буквы (согласно стандарту Unicode) или символа подчеркивания и содержать сколько угодно дополнительных букв, цифр и подчеркиваний. Имена чувствительны к регистру, однако нельзя использовать имена, которые различаются только регистром, т. е. язык не допускает создания переменных ИмяФайла и имяФайла.

Большинство ключевых слов и литералы не могут выступать в роли имен переменных.

пер ИмяФайла = "test.txt" // Корректное имя переменной
знч имяФайла = "test.txt" // Переменная с именем "имяФайла" уже определена
знч конструктор = 10 // Нельзя использовать ключевое слово для имени переменной
знч Истина = 10 // Нельзя использовать литерал типа Булево

При формировании имен переменных придерживайтесь следующих правил:

  • Имена переменных должны быть точными и лаконичными. Имя должно однозначно отражать суть переменной, например: Сотрудник, ЗакрытыеЗадачи, ОбщаяСуммаПлатежей. По возможности избегайте абстрактных имен, таких как Данные, Элемент, Объект и т. п., которые не добавляют понимания контекста.

  • Не используйте сокращения в именах переменных. Сокращения ухудшают читаемость и понимание кода. Исключениями являются общепринятые сокращения, например: Ид, Ндс, Фио.

  • Не используйте в качестве имен переменных имена типов-одиночек, чтобы сохранить возможность обращаться к ним по имени типа:

    метод ТекущаяОс(): Строка
        пер СредаИсполнения = "Windows"
        // Так можно вызвать метод типа-одиночки, если переименовать переменную "СредаИсполнения"
        возврат СредаИсполнения.ПолучитьПеременную("OS") // Неизвестный метод "Строка.ПолучитьПеременную"
        // Вызов метода типа-одиночки через полное имя
        возврат Стд::СредаИсполнения::СредаИсполнения.ПолучитьПеременную("OS")
    ;

См. также​

Последнее обновление