Url

Стд::Http::Url Доступность: КлиентИСервер

Унифицированный адрес ресурса (URL-ссылка), представленный в виде объекта.

Схема ссылки:

Схема://ИмяПользователя:Пароль@БазовыйUrl:Порт/ОтносительныйПуть?Параметры#Якорь

Пример ссылки:

http://username:password@1c.ru:80/applications/test?param=data#anchor

Сравнение ссылочное

Иерархия типа

Базовые типы: Объект

Примеры

Создание Url из строки.

пер Урл = новый Url("http://username:password@1c.ru:80/applications/test?param=data#anchor")

// Урл.Схема - http
// Урл.Хост - 1c.ru
// Урл.Путь - /applications/test
// Урл.Параметры.ПолучитьПервый("param") - data
// Урл.Порт - 80
// Урл.ИмяПользователя - username
// Урл.Пароль - password
// Урл.Якорь - anchor

Раскодированная ссылка:

// символ % экранирован
знч ЗакодированнаяСсылка = "http://1c.ru/applications/\%D1\%82\%D0\%B5\%D1\%81\%D1\%82?\%D0\%BF\%D0\%B0\%D1\%80\%D0\%B0\%D0\%BC\%D0\%B5\%D1\%82\%D1\%80=\%D0\%B7\%D0\%BD\%D0\%B0\%D1\%87\%D0\%B5\%D0\%BD\%D0\%B8\%D0\%B5"
знч Url = новый Url(ЗакодированнаяСсылка)
// Url.ВСтроку() - http://1c.ru/applications/тест?параметр=значение

Собрать произвольный Url по частям:

// http://127.0.0.1:8080/app/%D0%BF%D1%80%D0%B8%D0%BB%D0%BE%D0%B6%D0%B5%D0%BD%D0%B8%D0%B5?data=%D0%B4%D0%B0%D0%BD%D0%BD%D1%8B%D0%B5%20%D0%B7%D0%B0%D0%BF%D1%80%D0%BE%D1%81%D0%B0#%D0%B7%D0%B0%D0%B3%D0%BE%D0%BB%D0%BE%D0%B2%D0%BE%D0%BA%201 
пер Url = Url.СБазовымUrl("http://localhost")
            .СХостом("127.0.0.1")
            .СПортом(8080)
            .СПутем("/app/приложение")
            .СПараметрамиЗапроса("data=данные запроса")
            .СЯкорем("заголовок 1")

Конвертировать адрес FTP на SFTP:

метод ПерейтиВSftp(ИсходнаяСсылка: Url): Url
    возврат ИсходнаяСсылка.СоСхемой("sftp").СПортом(22)
;

Сформировать URL-ссылку на Яндекс: Карты с адресом:

метод ПолучитьСсылкуНаКартеПоАдресу(Адрес: Строка): Строка
	возврат Url.СБазовымUrl("https://maps.yandex.ru")
					.СПараметрамиЗапроса(новый ПараметрыUrl({"text": Адрес})))
				    .ВКодированнуюСтроку()
;

// ...
знч АдресКомпании = "Дмитровское шоссе, 9, Москва"
// https://maps.yandex.ru?text=%D0%94%D0%BC%D0%B8%D1%82%D1%80%D0%BE%D0%B2%D1%81%D0%BA%D0%BE%D0%B5%20%D1%88%D0%BE%D1%81%D1%81%D0%B5,%209,%20%D0%9C%D0%BE%D1%81%D0%BA%D0%B2%D0%B0
знч СсылкаНаКарту = ПолучитьСсылкуНаКартеПоАдресу(АдресКомпании)

Кодирование URL-строки с одиночными %:

// Будет выброшено исключение Исключение ИсключениеНедопустимыйФормат
// ссылка = новый Url("https://docs.ru/path%zz/path?text=title%201")
 
// "%zz" - не валидное процентное кодирование
пер Ссылка = новый Url("https://docs.ru/path%zz/path?text=title%201", Истина)
 
// https://docs.ru/path%25zz/path?text=title%201
Ссылка.ВКодированнуюСтроку()
 
// https://docs.ru/path%zz/path?text=title 1
Ссылка.ВСтроку()
 
//Будет выброшено исключение Исключение ИсключениеНедопустимыйФормат
// Ссылка = Url.СБазовымUrl("https://docs.ru")
//          .СПутем("path%zz")
 
Ссылка = Url.СБазовымUrl("https://docs.ru")
            .СПутем("path%zz", Истина)
 
// https://docs.ru/path%25zz
Ссылка.ВКодированнуюСтроку()
 
// https://docs.ru/path%zz
Ссылка.ВСтроку()

Раскодирование пути в URL-строке:

пер Ссылка = новый Url("https://docs.ru/path%20/%20path")
// "path / path"
Ссылка.Путь
// https://docs.ru/path%20/%20path
Ссылка.ВКодированнуюСтроку()

// Экранируем %, не раскодирую значение URL:
Ссылка = новый Url("https://docs.ru/path%20/%20path", Ложь)
// "path%20/%20path"
Ссылка.Путь
// https://docs.ru/path%2520/%2520path
Ссылка.ВКодированнуюСтроку()

Конструкторы

Url

Доступность: КлиентИСервер

Url(
Ссылка: Строка,
РаскодироватьЗначение: Булево = Истина)

Создает новый объект на основе указанного базового URL-адреса.

БазовыйUrl - URL-строка в любом виде (кодированный или не кодированный).
РаскодироватьЗначение - Значение БазовыйUrl будет предварительно раскодировано из URL кодировки, в противном случае значение будет использоваться "как есть".