Геопозиционирование

Стд::Геопозиционирование::Геопозиционирование Тип-одиночка Доступность: Клиент

Объект для работы с функцией геопозиционирования на клиенте.

Пример

метод ОбработчикПоддерживаетсяГеопозиционирование(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Сообщение = "ПоддерживаетсяГеопозиционирование: " + Геопозиционирование.ПоддерживаетсяГеопозиционирование()
    Сообщить(Сообщение)
;

метод ОбработчикПолучитьПровайдеры(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Поставщики = Геопозиционирование.ПолучитьПоставщиков()
    пер Сообщение = ""
     
    если Поставщики.Размер() == 0
        Сообщение = "Нет активных поставщиков"
    иначе
        Сообщение = "Поставщики: "
    
        для Поставщик из Поставщики
            Сообщение = Сообщение + Поставщик.Имя + ", "        
        ;
    ;
    
    Сообщить(Сообщение)
;

метод ОбработчикПолучитьТочныйПровайдер(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Поставщик = Геопозиционирование.ПолучитьСамогоТочногоПоставщика()
    
    если Поставщик != Неопределено
        пер Сообщение = "Поставщик: " + Поставщик.Имя
        Сообщить(Сообщение)
    иначе
        Сообщить("Не удалось получить поставщика")
    ;        
;

метод ОбработчикПолучитьПоследнееМестоположение(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Поставщик = Геопозиционирование.ПолучитьСамогоТочногоПоставщика()
    
    если Поставщик != Неопределено
        пер Положение = Поставщик.ПолучитьПоследнееМестоположение()    
        пер Сообщение = "Дата: " + Положение.Дата + ", Кооринаты: " + Положение.Координаты.ВСтроку()
        Сообщить(Сообщение)
    иначе
        Сообщить("Не удалось получить поставщика")
    ;
;

метод ОбработчикПолучитьТекущееМестоположение(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Поставщик = Геопозиционирование.ПолучитьСамогоТочногоПоставщика()
    
    если Поставщик != Неопределено
        пер Положение = Поставщик.ПолучитьТекущееМестоположение()     
        пер Сообщение = "Дата: " + Положение.Дата + ", Кооринаты: " + Положение.Координаты.ВСтроку()
        Сообщить(Сообщение)
    иначе
        Сообщить("Не удалось получить поставщика")
    ;
;

метод ОбработчикПодключитьОбработчикИзмененияМестоположения(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Поставщик = Геопозиционирование.ПолучитьСамогоТочногоПоставщика()      
    пер Длительность = 5с
    пер Дистанция = 0
	пер РаботаВФоне = Ложь
    
    если Поставщик.ПодключитьОбработчикИзмененияМестоположения(Длительность, Дистанция, РаботаВФоне, &ОбработкаМестоположения)
        Сообщить("Обработчик подключен...")
    иначе
        Сообщить("Не удалось подключить обработчик")
    ;
;

метод ОбработчикОтключитьОбработчикИзмененияМестоположения(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Поставщик = Геопозиционирование.ПолучитьСамогоТочногоПоставщика()
    
    Поставщик.ОтключитьОбработчикИзмененияМестоположения(&ОбработкаМестоположения)
    Поставщик.ОтключитьОбработчикИзмененияМестоположения(&ОбработкаМестоположенияВФоне)
    
    Сообщить("Обработчики отключены")
;

метод ОбработчикПодключитьОбработчикИзмененияВФоне(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Поставщик = Геопозиционирование.ПолучитьСамогоТочногоПоставщика()      
    пер Длительность = 5с
    пер Дистанция = 0
	пер РаботаВФоне = Истина
    
    если Поставщик.ПодключитьОбработчикИзмененияМестоположения(Длительность, Дистанция, РаботаВФоне, &ОбработкаМестоположенияВФоне)
        Сообщить("Обработчик подключен...")
    иначе
        Сообщить("Не удалось подключить обработчик")
    ;
;

метод ОбработкаМестоположения(Положение: ДанныеМестоположения)
    пер Сообщение = "Дата: " + Положение.Дата + ", Кооринаты: " + Положение.Координаты.ВСтроку()
    Сообщить(Сообщение)
;

метод ОбработкаМестоположенияВФоне(Положение: ДанныеМестоположения)
    пер Сообщение = "В фоне. Дата: " + Положение.Дата + ", Кооринаты: " + Положение.Координаты.ВСтроку()
    Сообщить(Сообщение)
;

Сравнение ссылочное

Иерархия типа

Базовые типы: Объект, Одиночка

---

Методы

ПоддерживаетсяГеопозиционирование

Доступность: Клиент

ПоддерживаетсяГеопозиционирование(): Булево

Проверяет, поддерживаются ли службы геопозиционирования.

---

ПолучитьПоставщика

Доступность: Клиент

ПолучитьПоставщика(ИмяПоставщика: Строка): ПоставщикГеопозиции?

Возвращает поставщика геопозиции по имени.

Возвращаемое значение - объект ПоставщикГеопозиции или Неопределенно, если поставщик геопозиции с указанным именем не найден.

---

ПолучитьПоставщиков

Доступность: Клиент

ПолучитьПоставщиков(): ЧитаемыйМассив<ПоставщикГеопозиции>

Возвращает доступных поставщиков геопозиции.

---

ПолучитьСамогоТочногоПоставщика

Доступность: Клиент

ПолучитьСамогоТочногоПоставщика(): ПоставщикГеопозиции?

Возвращает поставщика геопозиции, который обеспечивает максимальную точность определения координат. Если доступные провайдеры отсутствуют, возвращается Неопределенно.

---

ПолучитьСамогоЭнергосберегающегоПоставщика

Доступность: Клиент

ПолучитьСамогоЭнергосберегающегоПоставщика(): ПоставщикГеопозиции?

Возвращает поставщика геопозиции, который обеспечивает минимальное энергопотребление. Если доступные провайдеры отсутствуют, возвращается Неопределенно.

---

Список унаследованных методов

Объект

ВСтроку, ПолучитьТип, Представление