Перейти к основному содержимому

Файл

Стд::ВводВывод::Файлы::Файл Доступность: Сервер

Объект для работы с файлами и каталогами в файловой системе. Предоставляет доступ к базовым атрибутам файла.

Сравнение ссылочное

Иерархия типа​

Базовые типы: Объект

Примеры​

метод ЗаписатьИПрочитатьФайл()
    // Объект файла test.txt в несуществующем каталоге
    знч ФайлПутьНеНайден = новый Файл("test.txt", "НесуществующийКаталог")
    
    попытка
		исп ПотокЧтения = ФайлПутьНеНайден.ОткрытьПотокЧтения()
    поймать И: ИсключениеВводаВывода
	    // Системе не удается найти указанный путь
    ;       

    // Объект файла test.txt в домашнем каталоге пользователя, объявление через родительский каталог
    знч ФайлПуть = новый Файл("test.txt", Файлы.ПолучитьДомашнийКаталогПользователя())
    
    исп ПотокЗаписи = ФайлПуть.ОткрытьПотокЗаписи()
    // если файл отсутствует, он будет создан по существующему пути, иначе данные файла будут перезаписаны
    ПотокЗаписи.Записать("тест")
    
    // Объект файла test.txt в домашнем каталоге пользователя, объявление через часть пути
    знч ФайлЧастьПути = новый Файл(Файлы.ПолучитьДомашнийКаталогПользователя().Путь, ["test.txt"])
    
    // Проверка существования файла по указанному пути
    если ФайлЧастьПути.Существует()
        исп ПотокЧтения = ФайлЧастьПути.ОткрытьПотокЧтения()
        пер Текст = ПотокЧтения.ПрочитатьКакСтроку() // тест
    ;
;

метод ОчиститьПустыеВTemp()
  знч Temp = новый Файл(СредаИсполнения.ПолучитьПеременную("TEMP"))

  для Файл из Temp.Дочерние
      если Файл.ЭтоКаталог() и Файл.Дочерние.Пусто()
          Файлы.Удалить(Файл)
      ;
   ;   
;

Конструкторы​

Файл​

Доступность: Сервер

Файл(
Путь: Строка,
ДополнительныеЧастиПути: ЧитаемыйМассив<Строка>)
Перегрузка:
Файл(Путь: Строка, Родитель: Файл|Строка)

Соединяет части Путь и ДополнительныеЧастиПути, добавляя разделитель между каждой частью и создает объект связанный с файлом по данному пути. При создании не проверяется возможность физического создания файла в файловой системе.

Исключения​

ИсключениеНедопустимыйАргумент - при невалидных символах в пути к файлу.

Файл​

Доступность: Сервер

Файл(
Путь: Строка,
Родитель: Файл|Строка)
Перегрузка:
Файл(Путь: Строка, ДополнительныеЧастиПути: ЧитаемыйМассив<Строка>)

Создает объект, связанный с файлом с указанным именем Путь в родительском каталоге Родитель. При создании не проверяется возможность физического создания файла в файловой системе.

Исключения​

ИсключениеНедопустимыйАргумент - при невалидных символах в пути к файлу.

Свойства​

Дочерние​

Доступность: Сервер ТолькоЧтение

Дочерние: ЧитаемыйМассив<Файл>

Список файлов в каталоге. Пустой массив - если файл не является каталогом или не существует.

Изменен​

Доступность: Сервер ТолькоЧтение

Изменен: Момент?

Момент последнего изменения файла. Неопределено - если файл не существует.

Имя​

Доступность: Сервер ТолькоЧтение

Имя: Строка

Имя файла.

Примеры​

новый Файл("C:/test/file.txt") // Имя == "file.txt"

ИмяБезРасширения​

Доступность: Сервер ТолькоЧтение

ИмяБезРасширения: Строка

Имя файла без расширения.

Примеры​

новый Файл("C:/test/file.txt") // ИмяБезРасширения == "file"

Каталог​

Доступность: Сервер ТолькоЧтение

Каталог: Файл?

Родительский каталог.

Примеры​

новый Файл("C:/test/file.txt") // Родительский каталог == "C:/test"
новый Файл("C:/test/")         // Родительский каталог == "C:/"

Путь​

Доступность: Сервер ТолькоЧтение

Путь: Строка

Путь до файла.

Размер​

Доступность: Сервер ТолькоЧтение

Размер: РазмерБайтов?

Размер файла. Неопределено - если файл не существует.

Расширение​

Доступность: Сервер ТолькоЧтение

Расширение: Строка

Расширение файла (символы после последней точки в имени файла).

Примеры​

новый Файл("C:/test/file.txt")            // Расширение == "txt"
новый Файл("C:/test/this.is.file.txt")    // Расширение == "txt"
новый Файл("C:/test/.file")               // Расширение == "file"
новый Файл("C:/test/")                    // Расширение == ""

Скрытый​

Доступность: Сервер ТолькоЧтение

Скрытый: Булево?

Признак, является ли файл скрытым:

  • в Windows задается атрибутом 'Скрытый ('Hidden'),
  • в Linux, macOS наименование файла начинается с ".",
  • Неопределено - если файл не существует.

Создан​

Доступность: Сервер ТолькоЧтение

Создан: Момент?

Момент создания файла. Неопределено - если файл не существует.

Методы​

ВСтроку​

Доступность: Сервер

ВСтроку(): Строка
Переопределение: ВСтроку

Возвращает путь к файлу. Пример: "С:\\tests\file.txt".

ОткрытьПотокЗаписи​

Доступность: Сервер

ОткрытьПотокЗаписи(ЗаписатьВКонец: Булево = Ложь): ПотокЗаписи
Возвращает новый поток для записи в файл. ЗаписатьВКонец - Способ записи:

  • Истина - запись добавляется в существующий файл,
  • Ложь - содержимое файла удаляется, поток будет записан в начало.

ОткрытьПотокЧтения​

Доступность: Сервер

ОткрытьПотокЧтения(): ПотокЧтения
Возвращает новый поток для чтения из файла.

Существует​

Доступность: Сервер

Существует(): Булево
Проверяет, существует ли файл, соответствующий данному объекту.

ЭтоКаталог​

Доступность: Сервер

ЭтоКаталог(): Булево
Проверяет, является ли данный объект каталогом (если существует).

ЭтоСсылка​

Доступность: Сервер

ЭтоСсылка(): Булево
Проверяет, является ли данный объект символической ссылкой (если существует).

ЭтоФайл​

Доступность: Сервер

ЭтоФайл(): Булево
Проверяет, является ли данный объект файлом (если существует).

Список унаследованных методов​

Объект​

ПолучитьТип, Представление

Последнее обновление