Перейти к основному содержимому

ИзменяемоеЗапланированноеЗадание

Стд::Задания::ИзменяемоеЗапланированноеЗадание Доступность: Сервер

Изменяемое запланированное задание. Позволяет поменять некоторые опции запуска существующего запланированного задания.

Сравнение ссылочное

Иерархия типа​

Базовые типы: Объект

Примеры​

// Переопределение расписания, стратегий повтора, хранения результатов и регистрации событий.
знч Задание = ЗапланированныеЗадания.Изменить("МоеЗадание")
Задание.Настроить(
    Расписание = [
        Расписание.Ежемесячно(Время{8:00}, {Месяц.Февраль}, {23}),
        Расписание.Ежемесячно(Время{8:00}, {Месяц.Март}, {8})],
    ПовторыПриУспехе = СтратегияПовтораЗадания.Интервал(1с),
    ХранениеРезультатов = СтратегияХраненияРезультатовЗаданий.Отсутствует(),
    РегистрацияСобытий = СтратегияРегистрацииСобытийЗаданий.Ошибка)
Задание.Запланировать()

Методы​

Запланировать​

Доступность: Сервер

Запланировать(): ОписаниеЗадания
Задание планируется сразу, если нет активной транзакции, или после завершения активной транзакции.

Исключения​

ИсключениеТаймаутаЗадания - в случае долгого прерывания исполнения существующего задания. При возникновении исключения рекомендуется повторить операцию.

Примеры​

// Запуск задания при успешном завершении транзакции
исп Транзакция = Транзакции.Начать()

// ...
знч Задание1 = ЗапланированныеЗадания.Создать(&МойМодуль.МойМетод)
Задание1.Запланировать() // Задание не будет запланировано тут, т.к. есть активная транзакция

// ...
Транзакция.Фиксировать() // Задание будет запланировано тут

знч Задание2 = ЗапланированныеЗадания.Создать(&МойМодуль.МойМетод)
Задание2.Запланировать() // Задание будет запланировано тут

// Изменение задания с ключом "JobKey1", с повторными попытками в случае долгого прерывания существующего задания 
пер Попытка = 0
пока Попытка < 3
    пер Задание = ЗапланированныеЗадания.Изменить("JobKey1")
        .Настроить(ХранениеРезультатов = СтратегияХраненияРезультатовЗаданий.Дней(3))
    попытка
        Задание.Запланировать()
        возврат
    поймать Искл: ИсключениеТаймаутаЗадания
    ;

    Попытка = Попытка + 1
    Пауза(10s)
;

ЗапланироватьБезТранзакции​

Доступность: Сервер

ЗапланироватьБезТранзакции(): ОписаниеЗадания
Планирует задание сразу, независимо от наличия активной транзакции.

Примеры​

// Запуск задания немедленно
исп Транзакция = Транзакции.Начать()

// ...
знч Задание = ЗапланированныеЗадания.Создать(&МойМодуль.МойМетод)
Задание.ЗапланироватьБезТранзакции() // Задание будет запланировано тут
// ...
Транзакция.Фиксировать()

ЗапланироватьВТранзакции​

Доступность: Сервер

ЗапланироватьВТранзакции(): ОписаниеЗадания
Планирует задание после завершения активной транзакции. Если нет активной транзакции, выбрасывается исключение.

Примеры​

// Запуск задания немедленно
исп Транзакция = Транзакции.Начать()

// ...
знч Задание = ЗапланированныеЗадания.Создать(&МойМодуль.МойМетод)
Задание.ЗапланироватьВТранзакции() 
// ...
Транзакция.Фиксировать() // Задание будет запланировано тут

Настроить​

Доступность: Сервер

@ИменованныеПараметры
Настроить(
Расписание: Расписание|Обходимое<Расписание>,
Задержка: Длительность,
ПовторыПриУспехе: СтратегияПовтораЗадания,
ПовторыПриОшибке: СтратегияПовтораЗадания,
ХранениеРезультатов: СтратегияХраненияРезультатовЗаданий,
УсловияЗапускаНаМобильныхУстройствах: УсловияЗапускаЗаданияНаМобильныхУстройствах,
РегистрацияСобытий: СтратегияРегистрацииСобытийЗаданий
): ИзменяемоеЗапланированноеЗадание

Вызов возможен только с именованными параметрами

Меняет параметры запуска существующего задания. Возвращает этот же экземпляр ИзменяемоеЗапланированноеЗадание с новыми значениями параметров запуска.

Опциональный параметр Расписание задает расписание запуска задания. Если при вызове параметр не указан, расписание запуска изменяемого задания не меняется.

Опциональный параметр Задержка задает задержку начала выполнения относительно времени планирования задания. Задержка должна быть неотрицательной. Если задано расписание, то задержка игнорируется. Если при вызове параметр не указан, задержка начала выполнения изменяемого задания не меняется.

Опциональный параметр ПовторыПриОшибке задает стратегию повторных запусков задания, если оно завершилось с ошибкой. Если при вызове параметр не указан, стратегия повторных запусков изменяемого задания, если оно завершилось с ошибкой, не меняется.

Опциональный параметр ПовторыПриУспехе задает стратегию повторных запусков задания, если оно завершилось успешно. Если при вызове параметр не указан, стратегия повторных запусков изменяемого задания, если оно завершилось успешно, не меняется.

Опциональный параметр ХранениеРезультатов задает стратегию хранения результатов выполнения задания. Если при вызове параметр не указан, стратегия хранения результатов изменяемого задания не меняется.

Опциональный параметр УсловияЗапускаНаМобильныхУстройствах задает условия, которые должны соблюдаться при запуске запланированного задания на мобильных устройствах. Если при вызове параметр не указан, условия, которые должны соблюдаться при запуске изменяемого задания на мобильных устройствах, не меняются.

Опциональный параметр РегистрацияСобытий задает стратегию регистрации событий в журнале событий. Если при вызове параметр не указан, стратегия регистрации событий изменяемого задания не меняется.

Примеры​

Планирование задания, запускающего метод МойМетод модуля МойМодуль. В случае ошибки будет вызван обработчик МойОбработчикОшибки из модуля МойМодуль

метод ИзменитьЗадания()
    // Запуск задания с задержкой в 3 секунды.
    знч ЗаданиеСЗадержкой = ЗапланированныеЗадания.Изменить("КлючЗадания")
    ЗаданиеСЗадержкой.Настроить(Задержка = 3с)
    ЗаданиеСЗадержкой.Запланировать()
    
    // Запуск задания в 8 утра 23 февраля и 8 марта.
    знч Праздничное = ЗапланированныеЗадания.Изменить("КлючЗадания")
    Праздничное.Настроить(
        Расписание = [
            Расписание.Ежемесячно(Время{8:00}, {Месяц.Февраль}, {23}),
            Расписание.Ежемесячно(Время{8:00}, {Месяц.Март}, {8})],
        ПовторыПриОшибке = СтратегияПовтораЗадания.Интервал(1с))
    Праздничное.Запланировать()
;

Список унаследованных методов​

Объект​

ВСтроку, ПолучитьТип, Представление

Последнее обновление