ОтправкаДоставляемыхУведомлений

Стд::ДоставляемыеУведомления::ОтправкаДоставляемыхУведомлений Тип-одиночка Доступность: Сервер

Объект для работы с уведомлениями на сервере. Позволяет отправлять уведомления адресатам, а также получать информацию о том какие адресаты больше не подисаны на уведомления.

Сравнение ссылочное

Иерархия типа

Базовые типы: Объект, Одиночка

---

Примеры

В примере уведомления отправляются через все доступные сервисы.

метод ПослатьУведомление(Источник: Кнопка, Событие: СобытиеПриНажатии)
    пер Результат = ОтправитьУведомление()
    Сообщить(Результат)
;

@НаСервере
@ДоступноСКлиента
статический метод ОтправитьУведомление(): Строка
    возврат ОтправитьНаСервере()
;

@НаСервере
статический метод ОтправитьНаСервере(): Строка
    пер ИдПриложения = "com.e1c.mobile"

    пер ФайлССертификатом = новый Файл("Путь к файлу с сертификатом")    
    пер СодержимоеСертификатаВБайтах = ФайлССертификатом.ОткрытьПотокЧтения().ПрочитатьКакБайты()
    пер ДанныеАутентификацииApns = новый ДанныеАутентификацииApns(ИдПриложения, СодержимоеСертификатаВБайтах, "ПарольКСертификату")
        
    пер ФайлСКлючом = новый Файл("Путь к файлу с ключом")    
    пер СодержимоеКлючаВБайтах = ФайлСКлючом.ОткрытьПотокЧтения().ПрочитатьКакБайты()
    пер ДанныеАутентификацииFcm = новый ДанныеАутентификацииFcm(ИдПриложения, СодержимоеКлючаВБайтах)
    
    пер ДанныеАутентификацииHms = новый ДанныеАутентификацииHms(ИдПриложения, "ИдПроекта", "ИдКлиента", "СекретКлиента")

    пер ИдПолучателя = новый ИдПодписчикаДоставляемыхУведомлений()

    ИдПолучателя.ВидПодписчика = ВидПодписчикаДоставляемыхУведомлений.Fcm
    ИдПолучателя.ИдПриложения = ИдПриложения
    ИдПолучателя.ИдУстройства = "YQmZdrBF64dmWIwK-c7HE7ULQ3z_KNSyZRR89UrNSJkURoPOO2"
    
    пер Получатели = новый Массив<ИдПодписчикаДоставляемыхУведомлений>()
    Получатели.Добавить(ИдПолучателя)

    пер Триггер = новый ТриггерДоставляемыхУведомленийПоСпискуПолучателей()
    Триггер.Получатели = Получатели

    пер Уведомление = новый ДоставляемоеУведомление()

    Уведомление.Ид = "10001"
    Уведомление.Заголовок = "Привет из Элемента"
    Уведомление.Текст = "Тест отправки пушей из Элемента"    
    Уведомление.Данные = "Какие-то данные"
    Уведомление.Триггер = Триггер

    пер Результат = ОтправкаДоставляемыхУведомлений.Отправить(Уведомление, [ДанныеАутентификацииApns, ДанныеАутентификацииFcm, ДанныеАутентификацииHms])
    пер Сообщение = ""

    если Результат.ПолучитьИнформациюОПроблемахОтправки().Пусто()
        Сообщение = "Уведомление успешно отправлено"
    иначе
        Сообщение = ""
        для Проблема из Результат.ПолучитьИнформациюОПроблемахОтправки()
            Сообщение = Сообщение + Проблема.Описание + ", "
        ;
    ;

    возврат Сообщение
;

---

Методы

Отправить

Доступность: Сервер

Отправить(Уведомления: ДоставляемоеУведомление|ЧитаемыйМассив<ДоставляемоеУведомление>): РезультатОтправкиДоставляемыхУведомлений

Перегрузка:
Отправить(Уведомления: ДоставляемоеУведомление|ЧитаемыйМассив<ДоставляемоеУведомление>, ДанныеАутентификации: ЧитаемыйМассив<ДанныеАутентификацииДоставляемыхУведомлений>): РезультатОтправкиДоставляемыхУведомлений

Посылает уведомление и возвращает результат отправки

Уведомление - одно или несколько уведомлений.

ДанныеАутентификации автоматически берутся из панели управления и должны быть заданы на форме настроек мобильного приложения.

---

Отправить

Доступность: Сервер

Отправить(
Уведомления: ДоставляемоеУведомление|ЧитаемыйМассив<ДоставляемоеУведомление>,
ДанныеАутентификации: ЧитаемыйМассив<ДанныеАутентификацииДоставляемыхУведомлений>
): РезультатОтправкиДоставляемыхУведомлений

Перегрузка:
Отправить(Уведомления: ДоставляемоеУведомление|ЧитаемыйМассив<ДоставляемоеУведомление>): РезультатОтправкиДоставляемыхУведомлений

Посылает уведомление и возвращает результат отправки

Уведомление - одно или несколько уведомлений.

ДанныеАутентификации - массив объектов с данными аутентификации для подключения к сервисам.

---

Список унаследованных методов

Объект

ВСтроку, ПолучитьТип, Представление