Перейти к основному содержимому

Файл

Стд::ВводВывод::Файлы::Файл

Объект для работы с файлами и каталогами в файловой системе. Предоставляет доступ к базовым атрибутам файла.

Сравнение

Ссылочное

Иерархия типа​

Базовые типы: Объект

Примеры​

Общие примеры

метод ЗаписатьИПрочитатьФайл()
    // Объект файла test.txt в несуществующем каталоге
    знч ФайлПутьНеНайден = новый Файл("test.txt", "НесуществующийКаталог")
    
    попытка
		исп ПотокЧтения = ФайлПутьНеНайден.ОткрытьПотокЧтения()
    поймать И: ИсключениеВводаВывода
	    // Системе не удается найти указанный путь
    ;       

    // Объект файла test.txt в домашнем каталоге пользователя, объявление через родительский каталог
    знч ФайлПуть = новый Файл("test.txt", Файлы.ПолучитьДомашнийКаталогПользователя())
    
    исп ПотокЗаписи = ФайлПуть.ОткрытьПотокЗаписи()
    // если файл отсутствует, он будет создан по существующему пути, иначе данные файла будут перезаписаны
    ПотокЗаписи.Записать("тест")
    
    // Объект файла test.txt в домашнем каталоге пользователя, объявление через часть пути
    знч ФайлЧастьПути = новый Файл(Файлы.ПолучитьДомашнийКаталогПользователя().Путь, ["test.txt"])
    
    // Проверка существования файла по указанному пути
    если ФайлЧастьПути.Существует()
        исп ПотокЧтения = ФайлЧастьПути.ОткрытьПотокЧтения()
        пер Текст = ПотокЧтения.ПрочитатьКакСтроку() // тест
    ;
;

метод ОчиститьПустыеВTemp()
  знч Temp = новый Файл(СредаИсполнения.ПолучитьПеременную("TEMP"))

  для Файл из Temp.Дочерние
      если Файл.ЭтоКаталог() и Файл.Дочерние.Пусто()
          Файлы.Удалить(Файл)
      ;
   ;   
;

Конструкторы​

Файл​

Файл(
  Путь: Строка,
  ДополнительныеЧастиПути: ЧитаемыйМассив<Строка>)
Соединяет части Путь и ДополнительныеЧастиПути, добавляя разделитель между каждой частью и создает объект связанный с файлом по данному пути. При создании не проверяется возможность физического создания файла в файловой системе.

Исключения​

ИсключениеНедопустимыйАргумент - при невалидных символах в пути к файлу.

Перегрузка
Файл(Путь: Строка, Родитель: Файл|Строка)

Файл​

Файл(
  Путь: Строка,
  Родитель: Файл|Строка)
Создает объект, связанный с файлом с указанным именем Путь в родительском каталоге Родитель. При создании не проверяется возможность физического создания файла в файловой системе.

Исключения​

ИсключениеНедопустимыйАргумент - при невалидных символах в пути к файлу.

Перегрузка
Файл(Путь: Строка, ДополнительныеЧастиПути: ЧитаемыйМассив<Строка>)

Свойства​

Дочерние​

ТолькоЧтение

Дочерние: ЧитаемыйМассив<Файл>

Список файлов в каталоге. Пустой массив - если файл не является каталогом или не существует.

Изменен​

ТолькоЧтение

Изменен: Момент?

Момент последнего изменения файла. Неопределено - если файл не существует.

Имя​

ТолькоЧтение

Имя: Строка

Имя файла.

Примеры​

знч Файл = новый Файл("C:/test/file.txt") // Имя == "file.txt"

ИмяБезРасширения​

ТолькоЧтение

ИмяБезРасширения: Строка

Имя файла без расширения.

Примеры​

знч Файл = новый Файл("C:/test/file.txt") // ИмяБезРасширения == "file"

Каталог​

ТолькоЧтение

Каталог: Файл?

Родительский каталог.

Примеры​

пер Файл = новый Файл("C:/test/file.txt") // Родительский каталог == "C:/test"
Файл = новый Файл("C:/test/")         // Родительский каталог == "C:/"

Путь​

ТолькоЧтение

Путь: Строка

Путь до файла.

Размер​

ТолькоЧтение

Размер: РазмерБайтов?

Размер файла. Неопределено - если файл не существует.

Расширение​

ТолькоЧтение

Расширение: Строка

Расширение файла (символы после последней точки в имени файла).

Примеры​

пер Файл = новый Файл("C:/test/file.txt")            // Расширение == "txt"
Файл = новый Файл("C:/test/this.is.file.txt")    // Расширение == "txt"
Файл = новый Файл("C:/test/.file")               // Расширение == "file"
Файл = новый Файл("C:/test/")                    // Расширение == ""

Скрытый​

ТолькоЧтение

Скрытый: Булево?

Признак, является ли файл скрытым:

  • в Windows задается атрибутом 'Скрытый ('Hidden'),
  • в Linux, macOS наименование файла начинается с ".",
  • Неопределено - если файл не существует.

Создан​

ТолькоЧтение

Создан: Момент?

Момент создания файла. Неопределено - если файл не существует.

Методы​

ВСтроку​

ВСтроку(): Строка
Возвращает путь к файлу. Пример: "С:\\tests\file.txt".

Переопределение
Объект::ВСтроку

ОткрытьПотокЗаписи​

ОткрытьПотокЗаписи(ЗаписатьВКонец: Булево = Ложь): ПотокЗаписи
Возвращает новый поток для записи в файл. ЗаписатьВКонец - Способ записи:

  • Истина - запись добавляется в существующий файл,
  • Ложь - содержимое файла удаляется, поток будет записан в начало.

ОткрытьПотокЧтения​

ОткрытьПотокЧтения(): ПотокЧтения
Возвращает новый поток для чтения из файла.

Существует​

Существует(): Булево
Проверяет, существует ли файл, соответствующий данному объекту.

ЭтоКаталог​

ЭтоКаталог(): Булево
Проверяет, является ли данный объект каталогом (если существует).

ЭтоСсылка​

ЭтоСсылка(): Булево
Проверяет, является ли данный объект символической ссылкой (если существует).

ЭтоФайл​

ЭтоФайл(): Булево
Проверяет, является ли данный объект файлом (если существует).

Список унаследованных методов​

Объект​

ВСтроку (Переопределение)

ПолучитьТип

Представление

Последнее обновление