Перейти к основному содержимому

СистемаВзаимодействия

Стд::СистемаВзаимодействия::СистемаВзаимодействия Тип-одиночка

Минимальная поддерживаемая версия API сервера системы взаимодействия: версия 24. Версия API соответствует минимальной версии сервера системы взаимодействия "8.3.10". Версия API может быть указана в адресе сервера системы взаимодействия.

Предоставляет возможность работы с сервером системы взаимодействия.

Сравнение

Ссылочное

Иерархия типа​

Базовые типы: Объект, Одиночка

Методы​

Войти​

Войти(
КлючиПриложения: КлючиПриложенияВзаимодействия,
ИдПользователяПриложения: Ууид,
ИмяПользователяПриложения: Строка,
ПолноеИмяПользователяПриложения: Строка,
ПараметрыПриложения: ПараметрыПриложенияВзаимодействия,
ПривилегированныйРежим: Булево = Ложь,
Таймаут: Длительность = 15с
): Ууид
Войти в приложение взаимодействия с указанным пользователем. Если пользователь не зарегистрирован ранее, то в системе взаимодействия создается новый пользователь.

Возвращает идентификатор пользователя на сервере системы взаимодействия.

  • КлючиПриложения - Ключи шифрования приложения.
  • ИдПользователяПриложения - Идентификатор пользователя приложения.
  • ИмяПользователяПриложения - Краткое имя пользователя приложения.
  • ПолноеИмяПользователяПриложения - Полное имя пользователя приложения.
  • ПараметрыПриложения - Специальный объект, в котором содержатся параметры приложения системы взаимодействия.
  • ПривилегированныйРежим - Признак того, что вход должен быть выполнен в привилегированном (Истина) или обычном (Ложь) режиме.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ЗагрузитьВложение​

ЗагрузитьВложение(
Файл: Файл|Строка,
ТипСодержимого: Строка? = Неопределено,
Таймаут: Длительность = 15с,
Прокси: ИнтернетПрокси? = Неопределено
): ВложениеВзаимодействия
Загрузить вложение на сервер взаимодействия.

  • Файл - файл вложения.
  • ТипСодержимого - MIME тип содержимого. На основе расширения файла идет автоматическое вычисление типа. Если тип не указан или не удалось вычислить, то будет использовано значение application/octet-stream. Максимальная длина значения - 512 символов.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.
  • Прокси - прокси для подключения к хранилищу сервера взаимодействия.

Исключения​

ИсключениеСистемыВзаимодействия - если на сервере взаимодействия не настроено внешнее файловое хранилище или возникла проблема при загрузке. ИсключениеОграниченияСистемыВзаимодействия - если на сервере взаимодействия превышен лимит на загрузку файлов.

Перегрузка
ЗагрузитьВложение(Содержимое: Байты|ПотокЧтения, Имя: Строка, ТипСодержимого: Строка?, Таймаут: Длительность = 15с, Прокси: ИнтернетПрокси? = Неопределено): ВложениеВзаимодействия

ЗагрузитьВложение​

ЗагрузитьВложение(
Содержимое: Байты|ПотокЧтения,
Имя: Строка,
ТипСодержимого: Строка?,
Таймаут: Длительность = 15с,
Прокси: ИнтернетПрокси? = Неопределено
): ВложениеВзаимодействия
Загрузить вложение на сервер взаимодействия.

  • Содержимое - содержимое вложения.
  • Имя - имя вложения с учетом расширения. Например, "Картинка.png". Максимальная длина имени - 1024 символа.
  • ТипСодержимого - MIME тип содержимого. Если тип не указан, то будет использовано значение application/octet-stream. Максимальная длина значения - 512 символов.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.
  • Прокси - прокси для подключения к хранилищу сервера взаимодействия.

Исключения​

ИсключениеСистемыВзаимодействия - если на сервере взаимодействия не настроено внешнее файловое хранилище или возникла проблема при загрузке. ИсключениеОграниченияСистемыВзаимодействия - если на сервере взаимодействия превышен лимит на загрузку файлов.

Перегрузка
ЗагрузитьВложение(Файл: Файл|Строка, ТипСодержимого: Строка? = Неопределено, Таймаут: Длительность = 15с, Прокси: ИнтернетПрокси? = Неопределено): ВложениеВзаимодействия

НайтиИнтеграцию​

НайтиИнтеграцию(
ИдИнтеграции: Строка|Ууид,
Таймаут: Длительность = 15с
): ИнтеграцияВзаимодействия?
Возвращает интеграцию системы взаимодействия по ее идентификатору. Если интеграция не найдена, будет возвращено Неопределено.

  • ИдИнтеграции - Идентификатор интеграции, которую нужно получить.
  • Длительность - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

НайтиОбсуждение​

НайтиОбсуждение(
ИдОбсуждения: Строка|Ууид,
Таймаут: Длительность = 15с
): ОбсуждениеВзаимодействия?
Возвращает обсуждение взаимодействия по его идентификатору или ключу в параметре ИдОбсуждения.

  • ИдОбсуждения - Идентификатор обсуждения или его ключ.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

НайтиОбсуждения​

@ИменованныеПараметры
НайтиОбсуждения(
Вид: ВидОбсужденияВзаимодействия? = Неопределено,
Ключ: Строка? = Неопределено,
Видимость: Булево? = Неопределено,
ДатаОбновления: Момент? = Неопределено,
ТекущийПользовательУчастник: Булево? = Неопределено,
Участники: ЧитаемыйМассив<Ууид>? = Неопределено,
ИдИнтегарции: Ууид? = Неопределено,
ИдВнешнегоОбсуждения: Строка? = Неопределено,
ЛимитОбсуждений: Число = 100,
Таймаут: Длительность = 15с
): ЧитаемыйМассив<ОбсуждениеВзаимодействия>

Вызов возможен только с именованными параметрами

Возвращает список обсуждений, которые соответствуют установленным отборам.

  • Вид - Отбор по виду обсуждений.
  • Ключ- Отбор по ключу обсуждений.
  • Видимость - Отбор по видимости обсуждений.
  • ДатаОбновления - Отбор по дате обновления обсуждений. Будут возвращены обсуждения, у которых последнее сообщение было написано позже или в указанный момент времени.
  • ТекущийПользовательУчастник - Отобрать обсуждения, в которых участвует текущий пользователь взаимодействия.
  • Участники - Фильтр, позволяет отобрать обсуждения, в которых участвуют указанные участники. Если указан параметр ТекущийПользовательУчастник, тогда обсуждения будут фильтроваться сначала по этом полю и дополнительно по полю Участники
  • ИдИнтеграции - Фильтр позволяет отобрать обсуждения, относящиеся к определенной интеграции.
  • ИдВнешнегоОбсуждения - Фильтр в комбинации с параметром ИдИнтеграции, позволяет отобрать внешнее обсуждение, например обсуждение с указанным абонентом WhatsApp.
  • ЛимитОбсуждений - Ограничение количества обсуждений.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Особенности:

Только в привилегированном режиме доступны все обсуждения, не только те, в которых участвует текущий пользователь взаимодействия.

Примеры​

Получить обсуждение по пользовательскому ключу

метод ПолучитьОбсуждениеДляУведомлений(КлючОбсужденияДляУведомлений)
    знч СписокОбсуждений = НайтиОбсуждения(Ключ = КлючОбсужденияДляУведомлений)
    если СписокОбсуждений.Пустой()
        возврат СоздатьОбсуждениеДляУведмленийПользователя()
    ;
 
    возврат СписокОбсуждений[0]
;
 
метод ПолучитьИдентификаторОбсужденияДляУведомлений()
    // фиктивый ключ для примера, на самом деле он вычисляется по пользователю приложения
    знч КлючОбсужденияДляУведомлений = "Notification#105ea6f2-2e8f-11ed-a261-0242ac120002"
 
    знч Обсуждение = ПолучитьОбсуждениеДляУведомлений(КлючОбсужденияДляУведомлений)
    возврат Обсуждение.Ид
;

НайтиПользователейВзаимодействия​

@ИменованныеПараметры
НайтиПользователейВзаимодействия(
Имя: Строка? = Неопределено,
ПолноеИмя: Строка? = Неопределено,
ЭлектроннаяПочта: Строка? = Неопределено,
Телефон: Строка? = Неопределено,
КлючСопоставления: Строка? = Неопределено,
Заблокирован: Булево? = Неопределено,
ЛимитПользователей: Число = 100,
НачальныйПользователь: ПользовательВзаимодействия|Ууид|? = Неопределено,
Таймаут: Длительность = 15с
): ЧитаемыйМассив<ПользовательВзаимодействия>

Вызов возможен только с именованными параметрами

Возвращает список пользователей, соответствующий указанному отбору. Если значение параметра равно Неопределено, то отбор при поиске не будет использоваться.

  • Имя - Отбор по имени пользователя.
  • ПолноеИмя - Отбор по полному имени пользователя.
  • ЭлектроннаяПочта - Отбор по электронной почте пользователя.
  • Телефон - Отбор по номеру телефона пользователя.
  • КлючСопоставления - Отбор по ключу сопоставления пользователя.
  • Заблокирован - Отбор по признаку заблокирован у пользователя.
  • ЛимитПользователей - Ограничение на количество записей.
  • НачальныйПользователь - Начальный пользователь взаимодействия или его идентификатор в системе взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Метод доступен только в привилегированном режиме.

Примеры​

Найти пользователя в системе взаимодействия по его электронной почте

пер ПользовательВзаимодействия: ПользовательВзаимодействия?
знч НайденныеПользователи = СистемаВзаимодействия.НайтиПользователейВзаимодействия(
    ЭлектроннаяПочта = "user@company.ru")
если не НайденныеПользователи.Пусто()
    ПользовательВзаимодействия = НайденныеПользователи[0]      
;

НайтиСообщение​

НайтиСообщение(
ИдСообщения: Ууид,
Таймаут: Длительность = 15с
): СообщениеВзаимодействия?
Возвращает сообщение системы взаимодействия по его идентификатору. Если сообщение не найдено, будет возвращено Неопределено.

  • ИдСообщения - Идентификатор сообщения, которое нужно получить.
  • Длительность - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

НайтиШаблонСообщения​

НайтиШаблонСообщения(
ИдШаблона: Ууид,
Таймаут: Длительность = 15с
): ШаблонСообщенияВзаимодействия?
Производит поиск шаблона сообщения по его идентификатору.

  • ИдШаблона - Идентификатор шаблона сообщения Системы Взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ОбъединитьПриложения​

ОбъединитьПриложения(
ОбъединениеПриложений: ОбъединениеПриложенийВзаимодействия,
Таймаут: Длительность = 15с)
Объединяет приложения взаимодействия в единое пространство. Работает только в рамках одного абонента.

  • ОбъединениеПриложений - Объединение приложений взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Метод доступен только с правами администратора и под пользователем, который является владельцем абонента.

Исключения​

ИсключениеОбъединенияПриложенийСистемыВзаимодействия - если одно из приложений взаимодействия не существует.

ОжидатьНовыеСообщения​

ОжидатьНовыеСообщения(Таймаут: Длительность = 5м): ЧитаемыйМассив<СообщениеВзаимодействия>
Ожидать получение новых сообщений взаимодействия.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Отключиться​

Отключиться()
Отключает от сервера системы взаимодействия.

ОтменитьОбъединениеПриложений​

ОтменитьОбъединениеПриложений(
ИдПриложения: Ууид,
ИдПарногоПриложения: Ууид,
Таймаут: Длительность = 15с)
Отменяет объединение приложений взаимодействия.

  • ИдПриложения - Идентификатор приложения взаимодействия.
  • ИдПарногоПриложения - Идентификатор парного приложения взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Идентификаторы объединенных приложений взаимодействия можно получить с помощью метода ПолучитьОбъединенияПриложений.

Метод доступен только с правами администратора и под пользователем, который является владельцем абонента.

Исключения​

ИсключениеОбъединенияПриложенийСистемыВзаимодействия - если одно из приложений взаимодействия не существует.

ОтписатьсяОтОбсуждения​

ОтписатьсяОтОбсуждения(
ИдОбсуждения: Ууид,
Таймаут: Длительность = 15с)
Отписывает текущего пользователя от новых сообщений в указанном обсуждении по ИдОбсуждения. Если пользователь не подписан на обсуждение, то исключение не будет выброшено.

Исключения​

ИсключениеЗапретаДоступаСистемыВзаимодействия - если к обсуждению нет доступа. ИсключениеНеНайденОбъектСистемыВзаимодействия - если обсуждения не существует.

ПоддерживаютсяВложения​

ПоддерживаютсяВложения(Таймаут: Длительность = 15с): Булево
Возвращает признак, подключено ли внешнее хранилище файлов к серверу взаимодействия.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Подключиться​

Подключиться(
Сервер: Строка,
ПараметрыСоединения: ПараметрыЗащищенногоСоединения,
Таймаут: Длительность = 15с)
Подключает к серверу системы взаимодействия.

  • Сервер - Строка с адресом сервера взаимодействия, к которому выполняется подключение. По умолчанию используется адрес сервера 1С: Диалог.
  • ПараметрыСоединения - Параметры защищенного соединения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Перегрузка
Подключиться(Сервер: Строка, ФайлХранилища: Строка = "", ПарольХранилища: Секрет|Строка = "", ПарольКлюча: Секрет|Строка = "", Таймаут: Длительность = 15с)

Подключиться​

Подключиться(
Сервер: Строка,
ФайлХранилища: Строка = "",
ПарольХранилища: Секрет|Строка = "",
ПарольКлюча: Секрет|Строка = "",
Таймаут: Длительность = 15с)
Подключает к серверу системы взаимодействия.

  • Сервер - Строка с адресом сервера взаимодействия, к которому выполняется подключение. По умолчанию используется адрес сервера 1С: Диалог.
  • ФайлХранилища - Путь к файлу, содержащему сертификат сервера системы взаимодействия.
  • ПарольХранилища - Пароль для доступа к файлу-хранилищу.
  • ПарольКлюча - Пароль для доступа к сертификату системы взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Перегрузка
Подключиться(Сервер: Строка, ПараметрыСоединения: ПараметрыЗащищенногоСоединения, Таймаут: Длительность = 15с)

ПодключитьсяБезПроверкиСертификата​

ПодключитьсяБезПроверкиСертификата(
Сервер: Строка,
Таймаут: Длительность = 15с)
Подключает к серверу системы взаимодействия. Проверка сертификата при подключении не выполняется.

  • Сервер - Строка с адресом сервера взаимодействия, к которому выполняется подключение. По умолчанию используется адрес сервера 1С: Диалог.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПодписатьсяНаОбсуждение​

ПодписатьсяНаОбсуждение(
ИдОбсуждения: Ууид,
Таймаут: Длительность = 15с)
Подписывает текущего пользователя на новые сообщения в указанном обсуждении по ИдОбсуждения. В групповых обсуждениях это делается автоматически, при включении пользователя в участники. В контекстных обсуждениях это происходит только, когда пользователь написал сообщение в обсуждении или его упомянули в обсуждении.

Исключения​

ИсключениеЗапретаДоступаСистемыВзаимодействия - если к обсуждению нет доступа. ИсключениеНеНайденОбъектСистемыВзаимодействия - если обсуждения не существует.

Примеры​

метод ПодписатьсяНаКонтекстноеОбсуждение(ИдОбсуждения: Ууид)
    попытка
        СистемаВзаимодействия.ПодписатьсяНаОбсуждение(ИдОбсуждения)
    поймать Исключение: ИсключениеЗапретаДоступаСистемыВзаимодействия|ИсключениеНеНайденОбъектСистемыВзаимодействия
        // игнорируем  
    ;
;

ПолучитьВерсиюApi​

ПолучитьВерсиюApi(Таймаут: Длительность = 15с): Число
Возвращает текущую версию протокола взаимодействия с сервером взаимодействия.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьВерсиюСервераВзаимодействия​

ПолучитьВерсиюСервераВзаимодействия(Таймаут: Длительность = 15с): Строка
Возвращает версию сервера взаимодействия, к которому подключено текущее приложение.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьВидыВнешнихСистем​

ПолучитьВидыВнешнихСистем(Таймаут: Длительность = 15с): ЧитаемыйМассив<Строка>
Возвращает поддерживаемые сервером взаимодействия типы внешних систем.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьВремяОкончанияДоступностиОтвета​

ПолучитьВремяОкончанияДоступностиОтвета(
ИдОбсуждения: Ууид,
Таймаут: Длительность = 15с
): Момент?
Для интеграции типа WhatsApp получает время окончания 24-х часового окна для ответа. Для только что созданного обсуждения или обсуждения, не работающего с WhatsApp, возвращает Неопределено.

  • ИдОбсуждения - Идентификатор обсуждения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьИдПользователяВзаимодействия​

ПолучитьИдПользователяВзаимодействия(
ИдПользователяПриложения: Ууид,
Таймаут: Длительность = 15с
): Ууид?
Возвращает идентификатор пользователя в системе взаимодействия по его идентификатору пользователя.

  • ИдПользователяПриложения - Идентификатор пользователя приложения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Примеры​

// ранее известный идентификатор пользователя
знч ИдПользователяПриложения = Ууид{6c79fc60-2373-11ed-861d-0242ac120002}
знч ИдПользователяВСистемеВзаимодействия = СистемаВзаимодействия.ПолучитьИдПользователяВзаимодействия(ИдПользователяПриложения)
знч ПользовательВзаимодействия = СистемаВзаимодействия.ПолучитьПользователяВзаимодействия(ИдПользователяВСистемеВзаимодействия)

ПолучитьИдТекущегоПользователяВзаимодействия​

ПолучитьИдТекущегоПользователяВзаимодействия(Таймаут: Длительность = 15с): Ууид
Возвращает идентификатор текущего пользователя в системе взаимодействия.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьИнтеграции​

ПолучитьИнтеграции(
ЛимитИнтеграций: Число = 100,
Таймаут: Длительность = 15с
): ЧитаемыйМассив<ИнтеграцияВзаимодействия>
Возвращает все интеграции с внешними системами, созданные для приложения.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Исключения​

ИсключениеСистемыВзаимодействия - если метод вызван не с правами администратора

ПолучитьНепрочитанныеОбсуждения​

ПолучитьНепрочитанныеОбсуждения(
Видимые: Булево? = Неопределено,
ЛимитОбсуждений: Число = 100,
Таймаут: Длительность = 15с
): Массив<Ууид>
Возвращает массив идентификаторов непрочитанных обсуждений.

  • Видимые - Признак для фильтрации по свойству обсуждения Видимость.
  • ЛимитОбсуждений - Ограничение количества обсуждений, которое может вернуть метод (максимальное значение равно 100).
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьНепрочитанныеСообщения​

ПолучитьНепрочитанныеСообщения(
ИдОбсуждения: Ууид,
ЛимитСообщений: Число = 100,
Таймаут: Длительность = 15с
): Массив<СообщениеВзаимодействия>
Возвращает массив непрочитанных сообщений обсуждения.

  • ИдОбсуждения - Идентификатор обсуждения.
  • ЛимитСообщений - Ограничение количества сообщений, которое может вернуть метод (максимальное значение равно 100).
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьОбсуждения​

ПолучитьОбсуждения(
ИдОбсуждений: ЧитаемыйМассив<Ууид>,
Таймаут: Длительность = 15с
): Массив<ОбсуждениеВзаимодействия>
Возвращает обсуждения, соответствующие указанным идентификаторам ИдОбсуждений.

  • ИдОбсуждений - Список идентификаторов обсуждений.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьОбъединенияПриложений​

ПолучитьОбъединенияПриложений(Таймаут: Длительность = 15с): ЧитаемыйМассив<ОбъединениеПриложенийВзаимодействия>
Возвращает список объединений приложений взаимодействия в рамках абонента.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Метод доступен только с правами администратора и под пользователем, который является владельцем абонента.

ПолучитьОписаниеВнешнейСистемы​

ПолучитьОписаниеВнешнейСистемы(
ВидВнешнейСистемы: Строка,
Таймаут: Длительность = 15с
): ОписаниеВнешнейСистемыВзаимодействия?
Возвращает описание внешней системы взаимодействия. Если вид внешней системы не поддерживается на сервере Системы Взаимодействия, то вернет Неопределено.

  • ВидВнешнейСистемы - Вид внешней системы взаимодействия: "Telegram", "WhatsApp", "WebChat" и т.д.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьПользователяВзаимодействия​

ПолучитьПользователяВзаимодействия(
Ид: Ууид,
Таймаут: Длительность = 15с
): ПользовательВзаимодействия?
Возвращает пользователя взаимодействия по указанному идентификатору пользователя. Если пользователь не существует или к нему нет доступа, то будет возвращено Неопределено.

  • Ид - Идентификатор пользователя в системе взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьПочтуАбонента​

ПолучитьПочтуАбонента(Таймаут: Длительность = 15с): Строка
Возвращает почту абонента, на которую зарегистрировано текущее приложение взаимодействия.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Исключения​

ИсключениеЗапретаДоступаСистемыВзаимодействия - если пользователь не является администратором абонента в системе взаимодействия.

ПолучитьПриложениеАбонента​

ПолучитьПриложениеАбонента(
ИдПриложения: Ууид,
Таймаут: Длительность = 15с
): ПриложениеВзаимодействия?
Возвращает приложение взаимодействия абонента по его идентификатору. Если приложение не существует, то будет возвращено Неопределено.

  • ИдПриложения - идентификатор приложения взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьПриложенияАбонента​

ПолучитьПриложенияАбонента(Таймаут: Длительность = 15с): ЧитаемыйМассив<ПриложениеВзаимодействия>
Возвращает список приложений взаимодействия абонента.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьСообщения​

ПолучитьСообщения(
ИдОбсуждения: Ууид,
ЛимитСообщений: Число = 100,
НачальноеСообщение: Ууид? = Неопределено,
Таймаут: Длительность = 15с
): Массив<СообщениеВзаимодействия>
Возвращает массив сообщений обсуждения. Сообщения возвращаются в порядке от новых к старым.

  • ИдОбсуждения - Идентификатор обсуждения.
  • ЛимитСообщений - Ограничение количества сообщений, которое может вернуть метод (максимальное значение равно 100).
  • НачальноеСообщение - Сообщение, после которого будут получены сообщения обсуждения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьТекущегоПользователяВзаимодействия​

ПолучитьТекущегоПользователяВзаимодействия(Таймаут: Длительность = 15с): ПользовательВзаимодействия
Возвращает текущего пользователя взаимодействия.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьТекущееПриложение​

ПолучитьТекущееПриложение(Таймаут: Длительность = 15с): ПриложениеВзаимодействия
Возвращает текущее приложение взаимодействия.

  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

ПолучитьШаблоныСообщения​

ПолучитьШаблоныСообщения(
ИдИнтеграции: Ууид,
Таймаут: Длительность = 15с
): ЧитаемыйМассив<ШаблонСообщенияВзаимодействия>
Для интеграции типа WhatsApp возвращает список шаблонов сообщений. Для остальных интеграций возвращает пустой массив.

  • ИдИнтеграции - Идентификатор интеграции, для которой возвращается список шаблонов сообщений.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

РедактироватьИнтеграцию​

@ИменованныеПараметры
РедактироватьИнтеграцию(
ИдИнтеграции: Ууид,
Имя: Строка? = Неопределено,
ПараметрыВнешнейСистемы: ЧитаемоеСоответствие<Строка, Строка>? = Неопределено,
Ключ: Строка? = Неопределено,
Участники: ЧитаемыйМассив<Ууид>? = Неопределено,
Активно: Булево? = Неопределено,
Таймаут: Длительность = 15с)

Вызов возможен только с именованными параметрами

Изменяет существующую интеграцию взаимодействия.

  • Имя - Название интеграции для представления ее в пользовательском интерфейсе.
  • ВидВнешнейСистемы - Вид внешней системы взаимодействия: "Telegram", "WhatsApp", "WebChat" и т.д.
  • ПараметрыВнешнейСистемы - Предопределенные параметры подключения внешней системы (соответствие ключа и значения), уникальные для каждого типа внешней системы.
  • Ключ - Ключ интеграции системы взаимодействия. Если не пустая строка, то должен быть уникальным.
  • Участники - Список Ид участников по умолчанию для обсуждения, созданного интеграцией с внешней системой. По умолчанию используется пустой массив.
  • Активно - Определяет включение/отключение интеграции
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

РедактироватьОбсуждение​

РедактироватьОбсуждение(
ИдОбсуждения: Ууид,
Участники: ЧитаемыйМассив<Ууид>,
Название: Строка,
Таймаут: Длительность = 15с)
Изменяет существующее обсуждение взаимодействия.

  • ИдОбсуждения - Идентификатор обсуждения.
  • Участники - Идентификаторы участников обсуждения.
  • Название - Название обсуждения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

РедактироватьПользователяВзаимодействия​

@ИменованныеПараметры
РедактироватьПользователяВзаимодействия(
Ид: Ууид,
Имя: Строка? = Неопределено,
ПолноеИмя: Строка? = Неопределено,
ЭлектроннаяПочта: Строка? = Неопределено,
Телефон: Строка? = Неопределено,
КлючСопоставления: Строка? = Неопределено,
Изображение: Байты? = Неопределено,
Заблокирован: Булево? = Неопределено,
Таймаут: Длительность = 15с
): ПользовательВзаимодействия

Вызов возможен только с именованными параметрами

Редактирует данные пользователя взаимодействия по его идентификатору пользователя.

Если значение параметра равно Неопределено, то свойство пользователя взаимодействия не будет изменено при редактировании.

  • Ид - Идентификатор пользователя в системе взаимодействия.
  • Имя - Имя пользователя.
  • ПолноИмя - Полное имя пользователя.
  • ЭлектроннаяПочта - Электронная почта пользователя. Максимальная длина 255 символов.
  • Телефон - Номер телефона пользователя. Максимальная длина 32 символа.
  • КлючСопоставления - Ключ сопоставления пользователя.
  • Изображение- Аватар пользователя.
  • Заблокирован - Признак, что пользователь заблокирован в системе взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Доступно только в привилегированном режиме.

Исключения​

ИсключениеНеНайденОбъектСистемыВзаимодействия - если пользователь не существует в системе взаимодействия.

Примеры​

Изменить аватар у текущего пользователя системы взаимодействия

знч ИдПользователяПриложения = СистемаВзаимодействия.ПолучитьИдТекущегоПользователяВзаимодействия()
пер ФайлСАватаром = новый Файл("c:/tmp/avatar.png")
исп ПотокЧтения = ФайлСАватаром.ОткрытьПотокЧтения()
знч ИзображениеСАватаром: Байты = ПотокЧтения.ПрочитатьКакБайты()
 
СистемаВзамодействия.РедактироватьПользователяВзаимодействия(
    ИдПользователяПриложения = ИдПользователяПриложения,
    Изображение = ИзображениеСАватаром
)

РедактироватьСообщение​

РедактироватьСообщение(
ИдСообщения: Ууид,
Получатели: Ууид|ЧитаемыйМассив<Ууид>|? = Неопределено,
ТекстСообщения: Строка? = Неопределено,
Данные: Строка? = Неопределено,
Вложения: ЧитаемыйМассив<ВложениеВзаимодействия>? = Неопределено,
Таймаут: Длительность = 15с
): СообщениеВзаимодействия
Отредактировать существующее сообщение.

  • ИдСообщения - Идентификатор сообщения, которое нужно отредактировать.
  • Получатели - Получатели сообщения.
  • ТекстСообщения - Текст сообщения.
  • Данные - Данные сообщения.
  • Вложения - Вложения сообщения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Особенности:

  • Если какой-то из параметров Получатели, ТекстСообщения, Данные или Вложения равно Неопределено, то это значение в сообщении не будет изменено.

Исключения​

ИсключениеНеНайденОбъектСистемыВзаимодействия - если сообщение не существует. ИсключениеЗапретаДоступаСистемыВзаимодействия - если нет доступа к сообщению.

Примеры​

Добавить расчетный лист в существующее сообщение

знч ИдСообщения = Ууид{2a823855-4287-4700-9b49-766e98047bcf} // ранее созданное сообщение

// сохранение расчетного листа в C:/test/РасчетныйЛист.pdf
// ...
знч РасчетныйЛистPdf = новый Файл("C:/test/РасчетныйЛист.pdf")
знч Вложение = СистемаВзаимодействия.ЗагрузитьВложение(РасчетныйЛистPdf)

знч Сообщение = СистемаВзаимодействия.НайтиСообщение(ИдСообщения)
пер Вложения = новый Массив<Вложения>(Сообщение.Вложения)
Вложения.Добавить(Вложение)

СистемаВзаимодействия.РедактироватьСообщение(
	ИдСообщения = ИдСообщения,
	Вложения = Вложения)

Удаление вложения по имени из существующего сообщения

// ранее созданное сообщение с тремя вложениями
знч ИдСообщения = Ууид{2a823855-4287-4700-9b49-766e98047bcf}
знч ИмяВложенияДляУдаления = "price.xlsx"

знч Сообщение = СистемаВзаимодействия.НайтиСообщение(ИдСообщения)
пер Вложения = новый Массив<ВложениеВзаимодействия>()
для Вложение из Сообщение.Вложения
	если Вложение.Имя == ИмяВложенияДляУдаления 
		продолжить
	;

	Вложения.Добавить(Вложение)
;

СистемаВзаимодействия.РедактироватьСообщение(
	ИдСообщения = ИдСообщения,
	Вложения = Вложения)

СоздатьИнтеграцию​

СоздатьИнтеграцию(
Имя: Строка,
ВидВнешнейСистемы: Строка,
ПараметрыВнешнейСистемы: ЧитаемоеСоответствие<Строка, Строка>,
Участники: ЧитаемыйМассив<Ууид>,
Ключ: Строка? = Неопределено,
Активно: Булево = Истина,
Таймаут: Длительность = 15с
): Ууид
Создает и возвращает идентификатор интеграции с внешней системой в системе взаимодействия.

  • Имя - Название интеграции для представления ее в пользовательском интерфейсе.
  • ВидВнешнейСистемы - Вид внешней системы системы взаимодействия: "Telegram", "WhatsApp", "WebChat" и т.д.
  • ПараметрыВнешнейСистемы - Предопределенные параметры подключения внешней системы (соответствие ключа и значения), уникальные для каждого типа внешней системы.
  • Ключ - Ключ интеграции системы взаимодействия. Если не пустая строка, то должен быть уникальным.
  • Участники - Список Ид участников по умолчанию для обсуждения, созданного интеграцией с внешней системой. По умолчанию используется пустой массив.
  • Активно - Определяет включение/отключение интеграции
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Метод доступен только пользователям с правами администратора.

СоздатьЛичноеОбсуждение​

СоздатьЛичноеОбсуждение(
Участник: Ууид,
ВторойУчастник: Ууид? = Неопределено,
Таймаут: Длительность = 15с
): Ууид
Создает и возвращает идентификатор обсуждения в системе взаимодействия между двумя участниками. Обсуждение этого типа может быть только одно на приложение.

  • Участник - Идентификатор участника.
  • ВторойУчастник - Идентификатор второго участника. Если не указано, то будет использован идентификатор текущего пользователя.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

СоздатьОбсуждение​

СоздатьОбсуждение(
Участники: ЧитаемыйМассив<Ууид>,
Заголовок: Строка,
Ключ: Строка = "",
Видимость: Булево = Истина,
Таймаут: Длительность = 15с
): Ууид
Создает и возвращает идентификатор группового обсуждения в системе взаимодействия.

  • Участники - Идентификаторы участников обсуждения.
  • Название - Название обсуждения.
  • Ключ - Ключ обсуждения.
  • Видимость - Признак видимости обсуждения для интерактивной работы.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

СоздатьОбсуждениеСВнешнимПользователем​

СоздатьОбсуждениеСВнешнимПользователем(
ИдИнтеграции: Ууид,
ИдВнешнегоОбсуждения: Строка,
Участники: ЧитаемыйМассив<Ууид>,
Ключ: Строка = "",
Видимость: Булево = Истина,
Таймаут: Длительность = 15с
): Ууид
Создает обсуждение с пользователем внешней системы Системы Взаимодействия, например обсуждение WhatsApp.

  • ИдИнтеграции - Идентификатор интеграции, для которой создается обсуждение.
  • ИдВнешнегоОбсуждения - Идентификатор обсуждения во внешней системе. Для WhatsApp это номер телефона.
  • Участники - Идентификаторы участников обсуждения.
  • Название - Название обсуждения.
  • Ключ - Ключ обсуждения системы взаимодействия. Если не пустая строка, то должен быть уникальным.
  • Видимость - Признак видимости обсуждения для интерактивной работы.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

СоздатьПользователяВзаимодействия​

@ИменованныеПараметры
СоздатьПользователяВзаимодействия(
ИдПользователяПриложения: Ууид,
Имя: Строка,
ПолноеИмя: Строка,
ЭлектроннаяПочта: Строка = "",
Телефон: Строка = "",
КлючСопоставления: Строка = "",
Изображение: Байты,
Таймаут: Длительность = 15с
): Ууид

Вызов возможен только с именованными параметрами

Создает нового пользователя в системе взаимодействия.

  • ИдПользователяПриложения - идентификатор пользователя приложения.
  • Имя - имя пользователя.
  • ПолноИмя - полное имя пользователя.
  • ЭлектроннаяПочта - электронная почта пользователя. Максимальная длина 255 символов.
  • Телефон - номер телефона пользователя. Максимальная длина 32 символа.
  • КлючСопоставления - ключ сопоставления пользователя.
  • Изображение- аватар пользователя. Размер ограничен в 32КБ. Поддерживаются форматы, перечисленные в ФорматИзображения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Доступно только в привилегированном режиме.

Исключения​

ИсключениеОбъектСуществуетВСистемеВзаимодействия - если пользователь по ИдПользователяПриложения уже существует в системе взаимодействия.

Примеры​

Создать пользователя в системе взаимодействия для уведомления других пользователей

знч Идентификатор = Ууид{d0ee7a65-ffb9-43f5-a66d-2be0169b15dd}
знч Имя = "NotificationBot"
знч ПолноеИмя = "NotificationBot"
 
знч ИдПользователяДляУведомлений: Ууид = СистемаВзаимодействия.СоздатьПользователяВзаимодействия(
    ИдПользователяПриложения = Идентификатор,
    Имя = Имя,
    ПолноеИмя = ПолноеИмя,
    КлючСопоставления = ПолноеИмя)

СоздатьСообщение​

СоздатьСообщение(
ИдОбсуждения: Ууид,
Получатели: Ууид|ЧитаемыйМассив<Ууид>|? = Неопределено,
ТекстСообщения: Строка = "",
Данные: Строка = "",
Вложения: ЧитаемыйМассив<ВложениеВзаимодействия>,
Таймаут: Длительность = 15с
): Ууид
Создает и возвращает идентификатор сообщения, созданного по шаблону, в системе взаимодействия.

  • ИдОбсуждения - Идентификатор обсуждения.
  • Получатели - Идентификаторы получателей сообщения в системе взаимодействия.
  • ТекстСообщения - Текст сообщения.
  • Данные - Сериализованные в строку данные, которые дополнительно передаются в сообщении с типом данных "application/vnd.1c.json-internal".
  • Вложения - Вложения сообщения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Примеры​

Отправить сообщение с прайс-листом во вложениях:

// загрузим вложение на сервер взаимодействия
знч Файл = новый Файл("C:/test/price.xlsx")
знч Вложение = СистемаВзаимодействия.ЗагрузитьВложение(
	Содержимое = Файл.ОткрытьПотокЧтения(),
	Имя = "price.xlsx",
 	ТипСодержимого = "application/octet-stream"
)

знч ИдОбсуждения = Ууид{5c31ada8-4565-11ed-b878-0242ac120002} // ранее созданное обсуждение
// создадим сообщение с вложением
знч ИдСообщения = СистемаВзаимодействия.СоздатьСообщение(
    ИдОбсуждения = ИдОбсуждения,
    Вложения = [Вложение])

// получим сообщение и его вложение
знч Сообщение = СистемаВзаимодействия.НайтиСообщение(ИдСообщения)
знч ВходящееВложение = Сообщение.Вложения[0]
знч ИдВложения = ВходящееВложение.Ид // 1aee7439-6268-4f01-a4e3-432ac0dd79f4
знч ИмяФайла = ВходящееВложение.Имя // price.xlsx
знч РазмерФайла = ВходящееВложение.Размер // 1024(в байтах)
знч Содержимое: Байты = ВходящееВложение.ПолучитьБайты()

// сохраним вложение на компьютер
пер НовыйФайл = новый Файл("C:/test/price_new.xlsx")
исп ПотокЗаписи = НовыйФайл.ОткрытьПотокЗаписи()
ПотокЗаписи.Записать(Содержимое)

СоздатьСообщениеПоШаблону​

СоздатьСообщениеПоШаблону(
ИдОбсуждения: Ууид,
ИдШаблона: Ууид,
ЗначенияПараметровШаблона: ЧитаемыйМассив<Строка>? = Неопределено,
Получатели: Ууид|ЧитаемыйМассив<Ууид>|? = Неопределено,
Таймаут: Длительность = 15с
): Ууид
Создает и возвращает идентификатор сообщения в системе взаимодействия.

  • ИдОбсуждения - Идентификатор обсуждения.
  • ИдШаблона - Идентификатор шаблона сообщения Системы Взаимодействия.
  • ЗначенияПараметровШаблона - Содержит значения параметров шаблонного сообщения. По умолчанию - Неопределено.
  • Получатели - Идентификаторы получателей сообщения в системе взаимодействия.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Примеры​

Отправить шаблонное сообщение с указанием значения параметра:

знч ИдОбсуждения = Ууид{5c31ada8-4565-11ed-b878-0242ac120002} // ранее созданное обсуждение
знч КлючИнтеграцииWA = "ИнтеграцияWhatsApp" // ранее созданная интеграция

пер Интеграция = СистемаВзаимодействия.НайтиИнтеграцию(КлючИнтеграцииWA)
пер ШаблоныСообщения = СистемаВзаимодействия.ПолучитьШаблоныСообщения(Интеграция.Ид)
пер ШаблонПриветствия: ШаблонСообщенияВзаимодействия = ШаблоныСообщения[3]
        
пер ИдСообщения = СистемаВзаимодействия.СоздатьСообщениеПоШаблону(
                                ИдОбсуждения = ИдОбсуждения,
                                ИдШаблона =  ШаблонПриветствия.Ид,
                                ["Василий"])

УдалитьСообщение​

УдалитьСообщение(
ИдСообщения: Ууид,
Таймаут: Длительность = 15с)
Удаляет сообщение системы взаимодействия по его идентификатору.

  • ИдСообщения - Идентификатор сообщения, которое нужно удалить.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Исключения​

ИсключениеНеНайденОбъектСистемыВзаимодействия - если сообщение не существует. ИсключениеЗапретаДоступаСистемыВзаимодействия - если нет доступа к сообщению.

УстановитьПоследнееПрочитанноеСообщение​

УстановитьПоследнееПрочитанноеСообщение(
ИдОбсуждения: Ууид,
ИдСообщения: Ууид,
Таймаут: Длительность = 15с)
Устанавливает последнее прочитанное сообщение в обсуждении.

  • ИдОбсуждения - Идентификатор обсуждения.
  • ИдСообщения - Идентификатор сообщения.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

УстановитьПредставлениеШаблонаСообщения​

УстановитьПредставлениеШаблонаСообщения(
ИдШаблона: Ууид,
ПредставлениеШаблона: Строка,
ПредставленияПараметровШаблона: ЧитаемыйМассив<Строка>? = Неопределено,
Таймаут: Длительность = 15с)
Устанавливает представление шаблона и представления его параметров.

  • ИдШаблона - Идентификатор шаблона сообщения Системы Взаимодействия.
  • ПредставлениеШаблона - Представление шаблона сообщения Системы Взаимодействия.
  • ПредставленияПараметровШаблона - Представления параметров в тексте шаблона сообщения. По умолчанию Неопределено.
  • Таймаут - Таймаут, который определяет предельное время выполнения запроса к системе взаимодействия.

Список унаследованных методов​

Объект​

ВСтроку

ПолучитьТип

Представление

Последнее обновление