Область видимости

Область видимости — это часть программного кода, где доступны языковые конструкции: переменная, метод, перечисление, структура, исключение. Видимость ограничивается: блоками кода с помощью ключевого слова область, телом метода, циклами или границами скрипта с помощью аннотаций видимости.

Из вложенных областей видны внешние, но не наоборот.

@Локально
метод ВнутреннийМетод()
    Консоль.Записать("Локальный метод")
;

@Глобально
структура ПубличнаяСтруктура
    обз знч Значение: Число
;

метод ДемонстрацияВидимости()
    пер Общедоступная = "Видна во всем методе"
    
    область  // Новая область видимости
        пер Локальная = "Только внутри блока"
        Консоль.Записать(Общедоступная)  // Видит внешнюю переменную
        ВнутреннийМетод()
        
        // Демонстрация области видимости в цикле
        для Индекс = 1 по 3
            пер ЗначениеЦикла = Индекс * 10
            Консоль.Записать("Цикл: ${ЗначениеЦикла}")
            Консоль.Записать("Из блока: ${Локальная}")  // Видит внешнюю область
        ;
        Консоль.Записать(ЗначениеЦикла)  // Ошибка: Переменная «ЗначениеЦикла» не определена
    ;
    
    Консоль.Записать(Общедоступная)
    Консоль.Записать(Локальная)  // Ошибка: Переменная «Локальная» не определена
    
    пер Объект = новый ПубличнаяСтруктура(Значение = 42)
    Консоль.Записать("Значение: ${Объект.Значение}")
;

метод Скрипт()
    ДемонстрацияВидимости()
;

См. также​

См. также