ЗаписьXml

Стд::Xml::ЗаписьXml

Объект для потоковой записи XML. Непосредственно осуществляет запись в поток в процессе формирования XML, не храня записанные данные в памяти. Запись типов данных осуществляется в соответствии со стандартом XML для каноничной записи, если не указано иное.

Сравнение

Ссылочное

Иерархия типа

Базовые типы: Объект

Примеры

Общие примеры

Запись XML

Строковое представление исходного объекта для записи в XML

// {Заголовок={ИдВыгрузки=21fe9796-4735-4334-84fd-6d0b0b83b517, МоментВыгрузки=2023-10-17T11:48:22.000Z, ДанныеОтправителяXml=<Отправитель>Моя тестовая компания</Отправитель>},
//	Товары={
//		{Ид=И100, Наименование=Коробка картонная, Группа=Упаковка, Производитель={Наименование=ОКК, Страна=РФ, Штрихкод=1234567891234}, Характеристики={Толщина картона: 5мм, Вес: 300г}},
//		{Ид=И101, Наименование=Маркер, Группа=Канцтовары, Производитель={Наименование=GlobalMarker, Страна=undefined, Штрихкод=undefined}, Характеристики={Цвет: красный}},
//		{Ид=И102, Наименование=Набор крючков, Группа=ТоварыДляРыбалки, Производитель={Наименование=PNC, Страна=Палау, Штрихкод=2234567891234}, Характеристики=undefined}
//	}
// }

Код записи XML

// Объявление констант с простанством имен и префиксом для указания в корневом элементе
конст ПространствоИмен = "urn::my.test.company"
конст Префикс = "ns"

метод ЗаписатьXmlТовары(Товары: СтруктураТовары): Строка
    // Создание потока записи в строку, будет закрыт автоматически, так как объявлен через "исп"
    исп ПотокЗаписи = новый СтроковыйПотокЗаписи()

    // Отключение отступов и переносов в результирующем XML
    знч НастройкиЗаписиXml = новый НастройкиЗаписиXml()
	НастройкиЗаписиXml.ДобавлятьОтступы = Ложь
	
	// Создание объекта записи XML
	знч ЗаписьXml = новый ЗаписьXml(ПотокЗаписи, НастройкиЗаписиXml)
       
    // Запись объявления документа XML
    ЗаписьXml.ЗаписатьНачалоДокумента()
       
    // Корневой элемент Товары с префиксом и пространством имен
    ЗаписьXml.ЗаписатьНачалоЭлемента(Префикс + ":Товары")
	ЗаписьXml.ЗаписатьСоответствиеПространстваИмен(Префикс, ПространствоИмен)
    
    // Элемент Товары/Заголовок
    ЗаписатьЗаголовок(Товары.Заголовок, ЗаписьXml)
    
    // Элементы Товары/Товар
    Товары.Товары.ДляКаждого(Товар -> ЗаписатьТовар(Товар, ЗаписьXml))
    
    ЗаписьXml.ЗаписатьКонецДокумента()
    
    // Результат в виде строки XML
    возврат ПотокЗаписи.ВСтроку()
;

метод ЗаписатьЗаголовок(Заголовок: СтруктураЗаголовок, ЗаписьXml: ЗаписьXml)
    ЗаписьXml
        .ЗаписатьНачалоЭлемента("Заголовок")
        
        .ЗаписатьНачалоЭлемента("ИдВыгрузки")
        .ЗаписатьУуид(Заголовок.ИдВыгрузки)
        .ЗаписатьКонецЭлемента()
        
        .ЗаписатьНачалоЭлемента("МоментВыгрузки")
        .ЗаписатьМомент(Заголовок.МоментВыгрузки)
        .ЗаписатьКонецЭлемента()
        
        .ЗаписатьНачалоЭлемента("ДанныеОтправителяXml")
        .ЗаписатьСекциюCData(Заголовок.ДанныеОтправителяXml)
        .ЗаписатьКонецЭлемента()
    
        .ЗаписатьКонецЭлемента()
;

метод ЗаписатьТовар(Товар: СтруктураТовар, ЗаписьXml: ЗаписьXml)
    ЗаписьXml
        .ЗаписатьНачалоЭлемента("Товар")
        .ЗаписатьАтрибут("Ид", Товар.Ид)
        .ЗаписатьАтрибут("Наименование", Товар.Наименование)
        .ЗаписатьАтрибут("Группа", Товар.Группа)
        
    ЗаписатьПроизводитель(Товар.Производитель, ЗаписьXml)
    
    ЗаписатьХарактеристики(Товар.Характеристики, ЗаписьXml)

    ЗаписьXml.ЗаписатьКонецЭлемента()
;

метод ЗаписатьПроизводитель(Производитель: СтруктураПроизводитель, ЗаписьXml: ЗаписьXml)
    ЗаписьXml
        .ЗаписатьНачалоЭлемента("Производитель")
        .ЗаписатьАтрибут("Наименование", Производитель.Наименование)
        
    если Производитель.Страна != Неопределено
        ЗаписьXml.ЗаписатьАтрибут("Страна", Производитель.Страна)
    ;
    
    если Производитель.Штрихкод != Неопределено
        ЗаписьXml.ЗаписатьАтрибутЧисло("Штрихкод", Производитель.Штрихкод)
    ;

    ЗаписьXml.ЗаписатьКонецЭлемента()
;

метод ЗаписатьХарактеристики(Характеристики: Соответствие<Строка, Строка>?, ЗаписьXml: ЗаписьXml)
    если Характеристики != Неопределено и Характеристики.Размер() > 0        
        ЗаписьXml.ЗаписатьКомментарий("Необязательный элемент")        
        ЗаписьXml.ЗаписатьНачалоЭлемента("Характеристики")
        
        Характеристики.ДляКаждого((Элемент) ->
            ЗаписьXml
                .ЗаписатьНачалоЭлемента("Характеристика")
                .ЗаписатьАтрибут("Имя", Элемент.Ключ)
                .ЗаписатьАтрибут("Значение", Элемент.Значение)
                .ЗаписатьКонецЭлемента())
        
        ЗаписьXml.ЗаписатьКонецЭлемента()
    ;
;

Результат записи в строку XML

<?xml version="1.0" encoding="UTF-8"?>
<ns:Товары xmlns:ns="urn::my.test.company">
    <Заголовок>
        <ИдВыгрузки>21fe9796-4735-4334-84fd-6d0b0b83b517</ИдВыгрузки>
        <МоментВыгрузки>2023-10-17T11:48:22Z</МоментВыгрузки>
        <ДанныеОтправителяXml><![CDATA[<Отправитель>Моя тестовая компания</Отправитель>]]></ДанныеОтправителяXml>
    </Заголовок>
    <Товар Ид="И100" Наименование="Коробка картонная" Группа="Упаковка">
        <Производитель Наименование="ОКК" Страна="РФ" Штрихкод="1234567891234"/>
        <!-- Необязательный элемент -->
        <Характеристики>
            <Характеристика Имя="Толщина картона" Значение="5мм"/>
            <Характеристика Имя="Вес" Значение="300г"/>
        </Характеристики>
    </Товар>
    <Товар Ид="И101" Наименование="Маркер" Группа="Канцтовары">
        <Производитель Наименование="GlobalMarker"/>
        <!-- Необязательный элемент -->
        <Характеристики>
            <Характеристика Имя="Цвет" Значение="красный"/>
        </Характеристики>
    </Товар>
    <Товар Ид="И102" Наименование="Набор крючков" Группа="ТоварыДляРыбалки">
        <Производитель Наименование="PNC" Страна="Палау" Штрихкод="2234567891234"/>
    </Товар>
</ns:Товары>

Запись значений атрибутов и элементов различных типов

Код записи XML

метод ЗаписатьXmlТипы(): Строка
    исп ПотокЗаписи = новый СтроковыйПотокЗаписи()
    знч ЗаписьXml = новый ЗаписьXml(ПотокЗаписи)
    
    ЗаписьXml
        .ЗаписатьНачалоДокумента()
        .ЗаписатьНачалоЭлемента("Типы")
        
        // Атрибуты
        .ЗаписатьНачалоЭлемента("Атрибуты")
        .ЗаписатьАтрибут("Строка", "Строка")
        .ЗаписатьАтрибутБайты("Байты", Байты{74657374})
        .ЗаписатьАтрибутБайтыBase64("БайтыBase64", Байты{74657374})
        .ЗаписатьАтрибутБулево("Булево", Истина)
        .ЗаписатьАтрибутВремя("Время", Время{23:59:59.999})
        .ЗаписатьАтрибутДата("Дата", Дата{2023-01-01})
        .ЗаписатьАтрибутДатаВремя("ДатаВремя", ДатаВремя{2023-01-01 23:59:59.999})
        .ЗаписатьАтрибутДлительность("Длительность", 144ч5мс)
        .ЗаписатьАтрибутМомент("Момент", Момент{2020-04-16T20:30:40.345Z})
        .ЗаписатьАтрибутУуид("Ууид", Ууид{21fe9796-4735-4334-84fd-6d0b0b83b517})
        .ЗаписатьАтрибутЧисло("Число", 123.45)
        .ЗаписатьКонецЭлемента()

        // Элементы
        .ЗаписатьНачалоЭлемента("Элементы")
        
        .ЗаписатьНачалоЭлемента("Строка")
        .ЗаписатьТекст("Строка")
        .ЗаписатьКонецЭлемента()
        
        .ЗаписатьНачалоЭлемента("Байты")
        .ЗаписатьБайты(Байты{74657374})
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("БайтыBase64")
        .ЗаписатьБайтыBase64(Байты{74657374})
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("Булево")
        .ЗаписатьБулево(Истина)
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("Время")
        .ЗаписатьВремя(Время{23:59:59.999})
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("Дата")
        .ЗаписатьДату(Дата{2023-01-01})
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("ДатаВремя")
        .ЗаписатьДатаВремя(ДатаВремя{2023-01-01 23:59:59.999})
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("Длительность")
        .ЗаписатьДлительность(144ч5мс)
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("Момент")
        .ЗаписатьМомент(Момент{2020-04-16T20:30:40.345Z})
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("Ууид")
        .ЗаписатьУуид(Ууид{21fe9796-4735-4334-84fd-6d0b0b83b517})
        .ЗаписатьКонецЭлемента()

        .ЗаписатьНачалоЭлемента("Число")
        .ЗаписатьЧисло(123.45)
        .ЗаписатьКонецЭлемента()
        
        .ЗаписатьКонецЭлемента()    
        .ЗаписатьКонецЭлемента()
        .ЗаписатьКонецДокумента()
    
    возврат ПотокЗаписи.ВСтроку()
;

Результат записи в строку XML

<?xml version="1.0" encoding="UTF-8"?>
<Типы>
    <Атрибуты Строка="Строка" Байты="74657374" БайтыBase64="dGVzdA" Булево="true" Время="23:59:59.999"
              Дата="2023-01-01" ДатаВремя="2023-01-01T23:59:59.999" Длительность="PT144H0.005S" Момент="2020-04-16T20:30:40.345Z"
              Ууид="21fe9796-4735-4334-84fd-6d0b0b83b517" Число="123.45" />
    <Элементы>
        <Строка>Строка</Строка>
        <Байты>74657374</Байты>
        <БайтыBase64>dGVzdA</БайтыBase64>
        <Булево>true</Булево>
        <Время>23:59:59.999</Время>
        <Дата>2023-01-01</Дата>
        <ДатаВремя>2023-01-01T23:59:59.999</ДатаВремя>
        <Длительность>PT144H0.005S</Длительность>
        <Момент>2020-04-16T20:30:40.345Z</Момент>
        <Ууид>21fe9796-4735-4334-84fd-6d0b0b83b517</Ууид>
        <Число>123.45</Число>
    </Элементы>
</Типы>

См. также

ЧтениеXml

Конструкторы

ЗаписьXml

ЗаписьXml(
Поток: ПотокЗаписи,
Настройки: НастройкиЗаписиXml,
Кодировка: Кодировка|Строка = Кодировка.Utf8)

Конструктор записи XML в поток Поток с настройками Настройки в кодировке Кодировка.

Методы

ЗаписатьАтрибут

ЗаписатьАтрибут(
Имя: Строка,
Значение: Строка,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение Значение атрибута Имя с пространством имен ПространствоИмен. Атрибутов может быть произвольное количество. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента. ИсключениеНедопустимоеСостояние - если текущий узел не является началом элемента.

ЗаписатьАтрибутБайты

ЗаписатьАтрибутБайты(
Имя: Строка,
Значение: Байты,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Байты Значение в шестнадцатеричной кодировке в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьАтрибутБайтыBase64

ЗаписатьАтрибутБайтыBase64(
Имя: Строка,
Значение: Байты,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Байты Значение как число в кодировке Base64 в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьАтрибутБулево

ЗаписатьАтрибутБулево(
Имя: Строка,
Значение: Булево,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Булево Значение в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьАтрибутВремя

ЗаписатьАтрибутВремя(
Имя: Строка,
Значение: Время,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Время Значение в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьАтрибутДата

ЗаписатьАтрибутДата(
Имя: Строка,
Значение: Дата,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Дата Значение в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьАтрибутДатаВремя

ЗаписатьАтрибутДатаВремя(
Имя: Строка,
Значение: ДатаВремя,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа ДатаВремя Значение в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьАтрибутДлительность

ЗаписатьАтрибутДлительность(
Имя: Строка,
Значение: Длительность,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Длительность Значение в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьАтрибутМомент

ЗаписатьАтрибутМомент(
Имя: Строка,
Значение: Момент,
ПространствоИмен: Строка
): ЗаписьXml

Записывает значение типа Момент Значение в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

Перегрузка
ЗаписатьАтрибутМомент(Имя: Строка, Значение: Момент, ЧасовойПояс: ЧасовойПояс? = Неопределено, ПространствоИмен: Строка? = Неопределено): ЗаписьXml

ЗаписатьАтрибутМомент

ЗаписатьАтрибутМомент(
Имя: Строка,
Значение: Момент,
ЧасовойПояс: ЧасовойПояс? = Неопределено,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Момент Значение в атрибут Имя с пространством имен ПространствоИмен. Если указан часовой пояс, значение преобразуется к данному часовому поясу. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

Перегрузка
ЗаписатьАтрибутМомент(Имя: Строка, Значение: Момент, ПространствоИмен: Строка): ЗаписьXml

ЗаписатьАтрибутУуид

ЗаписатьАтрибутУуид(
Имя: Строка,
Значение: Ууид,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Ууид Значение в атрибут Имя с пространством имен ПространствоИмен. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьАтрибутЧисло

ЗаписатьАтрибутЧисло(
Имя: Строка,
Значение: Число,
ПространствоИмен: Строка? = Неопределено
): ЗаписьXml

Записывает значение типа Число Значение в атрибут Имя с пространством имен ПространствоИмен. Целые числа записываются без десятичного разделителя и дробной части. Атрибут может идентифицироваться полным именем или локальным именем и URI пространства имен. Атрибуты должны записываться непосредственно после записи начала элемента, иначе вызывается исключение.

Исключения

ЗаписатьБайты

ЗаписатьБайты(Значение: Байты): ЗаписьXml

Записывает текст элемента как Байты в шестнадцатеричной кодировке. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьБайтыBase64

ЗаписатьБайтыBase64(Значение: Байты): ЗаписьXml

Записывает текст элемента как Байты в кодировке Base64. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьБезОбработки

ЗаписатьБезОбработки(Значение: Строка): ЗаписьXml

Записывает XML-фрагмент текста Значение без обработки в результирующий текст. Например, можно приготовить фрагмент XML-документа и потом вставить его в целевой документ с помощью данного метода.

Следует быть очень осторожным с применением данного метода, так как размещаемый фрагмент не проверяется, что может сделать XML-документ синтаксически некорректным. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи фрагмента текста.

ЗаписатьБулево

ЗаписатьБулево(Значение: Булево): ЗаписьXml

Записывает текст элемента как тип Булево. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьВремя

ЗаписатьВремя(Значение: Время): ЗаписьXml

Записывает текст элемента как тип Время. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьДатаВремя

ЗаписатьДатаВремя(Значение: ДатаВремя): ЗаписьXml

Записывает текст элемента как ДатаВремя. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьДату

ЗаписатьДату(Значение: Дата): ЗаписьXml

Записывает текст элемента как тип Дата. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

ЗаписатьДлительность

ЗаписатьДлительность(Значение: Длительность): ЗаписьXml

Записывает текст элемента как тип Длительность. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьИнструкциюОбработки

ЗаписатьИнструкциюОбработки(
Цель: Строка,
Данные: Строка
): ЗаписьXml

Записывает инструкцию обработки XML-файла. Цель - Адрес инструкции. Данные - Данные. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьКомментарий

ЗаписатьКомментарий(Комментарий: Строка): ЗаписьXml

Записывает комментарий Комментарий. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьКонецДокумента

ЗаписатьКонецДокумента()

Закрывает все незакрытые теги.

Исключения

ИсключениеЗаписиXml - при ошибке записи XML.

ЗаписатьКонецЭлемента

ЗаписатьКонецЭлемента(ДобавлятьОтступы: Булево? = Неопределено): ЗаписьXml

Завершает запись элемента XML. Каждому вызову метода ЗаписатьНачалоЭлемента должен соответствовать вызов данного метода. Параметр ДобавлятьОтступы указывает, нужно ли использовать отступ и перенос на новую строку при записи элемента. При значении Неопределено используется значение из ДобавлятьОтступы. Возвращает текущий экземпляр.

Исключения

ИсключениеНедопустимоеСостояние - если не найден соответствующий узел начала элемента.

ЗаписатьМомент

ЗаписатьМомент(
Значение: Момент,
ЧасовойПояс: ЧасовойПояс? = Неопределено
): ЗаписьXml

Записывает текст элемента как тип Момент. Если указан часовой пояс, значение преобразуется к данному часовому поясу. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьНачалоДокумента

ЗаписатьНачалоДокумента(): ЗаписьXml

В начало документа помещается текст следующего вида: <?Xml version="1.0" encoding="UTF-8"?>. Данный метод должен быть вызван перед другими операциями записи Xml, иначе будет выброшено исключение. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента. ИсключениеНедопустимоеСостояние - если метод вызван после других операций записи XML.

ЗаписатьНачалоЭлемента

ЗаписатьНачалоЭлемента(
Имя: Строка,
ПространствоИмен: Строка? = Неопределено,
ДобавлятьОтступы: Булево? = Неопределено
): ЗаписьXml

Записывает начало элемента Имя в пространстве имен ПространствоИмен.
Параметр ДобавлятьОтступы указывает, нужно ли использовать отступ и перенос на новую строку при записи элемента. При значении Неопределено используется значение из ДобавлятьОтступы. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - если соответствие пространства имен записано не при записи вышестоящего элемента или не при записи данного элемента.

ЗаписатьСекциюCData

ЗаписатьСекциюCData(Данные: Строка): ЗаписьXml

Записывает данные Данные секции CDATA. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи секции.

ЗаписатьСоответствиеПространстваИмен

ЗаписатьСоответствиеПространстваИмен(
Префикс: Строка,
ПространствоИмен: Строка
): ЗаписьXml

Записывает соответствие префикса Префикс и URI пространства имен ПространствоИмен. Данный метод должен вызываться после обращения к методу ЗаписатьНачалоЭлемента. При передаче пустого префикса или префикса равного "xmlns" устанавливает соответствие префикса пространства по умолчанию (xmlns) и переданного URI. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - если текущий узел не является началом элемента.

ЗаписатьСсылкуНаСущность

ЗаписатьСсылкуНаСущность(ИмяСсылки: Строка): ЗаписьXml

Осуществляет запись ссылки на сущность ИмяСсылки. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьТекст

ЗаписатьТекст(Текст: Строка): ЗаписьXml

Записывает текст элемента. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьТипДокумента

ЗаписатьТипДокумента(
Имя: Строка,
ВнутреннееПодмножество: Строка? = Неопределено,
SystemId: Строка? = Неопределено,
PublicId: Строка? = Неопределено
): ЗаписьXml

Записывает секцию DTD. Имя - Имя документа. ВнутреннееПодмножество - Внутреннее подмножество (собственно определение типа документа). SystemId - Системный идентификатор документа. PublicId - Публичный идентификатор документа. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента. ИсключениеНедопустимоеСостояние - если запись вызвана повторно или после начала записи тела XML.

ЗаписатьУуид

ЗаписатьУуид(Значение: Ууид): ЗаписьXml

Записывает текст элемента как тип Ууид. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

ЗаписатьЧисло

ЗаписатьЧисло(Значение: Число): ЗаписьXml

Записывает текст элемента как тип Число. Целые числа записываются без десятичного разделителя и дробной части. Перед вызовом данного метода должен быть вызван метод ЗаписатьНачалоЭлемента. Возвращает текущий экземпляр.

Исключения

ИсключениеЗаписиXml - при ошибке записи элемента.

Список унаследованных методов

Объект

ВСтроку

ПолучитьТип

Представление

Иерархия типа​

Примеры​

См. также​

Конструкторы​

ЗаписьXml​

Методы​

ЗаписатьАтрибут​

Исключения​

ЗаписатьАтрибутБайты​

Исключения​

ЗаписатьАтрибутБайтыBase64​

Исключения​

ЗаписатьАтрибутБулево​

Исключения​

ЗаписатьАтрибутВремя​

Исключения​

ЗаписатьАтрибутДата​

Исключения​

ЗаписатьАтрибутДатаВремя​

Исключения​

ЗаписатьАтрибутДлительность​

Исключения​

ЗаписатьАтрибутМомент​

Исключения​

ЗаписатьАтрибутМомент​

Исключения​

ЗаписатьАтрибутУуид​

Исключения​

ЗаписатьАтрибутЧисло​

Исключения​

ЗаписатьБайты​

Исключения​

ЗаписатьБайтыBase64​

Исключения​

ЗаписатьБезОбработки​

Исключения​

ЗаписатьБулево​

Исключения​

ЗаписатьВремя​

Исключения​

ЗаписатьДатаВремя​

Исключения​

ЗаписатьДату​

ЗаписатьДлительность​

Исключения​

ЗаписатьИнструкциюОбработки​

Исключения​

ЗаписатьКомментарий​

Исключения​

ЗаписатьКонецДокумента​

Исключения​

ЗаписатьКонецЭлемента​

Исключения​

ЗаписатьМомент​

Исключения​

ЗаписатьНачалоДокумента​

Исключения​

ЗаписатьНачалоЭлемента​

Исключения​

ЗаписатьСекциюCData​

Исключения​

ЗаписатьСоответствиеПространстваИмен​

Исключения​

ЗаписатьСсылкуНаСущность​

Исключения​

ЗаписатьТекст​

Исключения​

ЗаписатьТипДокумента​

Исключения​

ЗаписатьУуид​

Исключения​

ЗаписатьЧисло​

Исключения​

Список унаследованных методов​

Объект​

Иерархия типа

Примеры

См. также

Конструкторы

ЗаписьXml

Методы

ЗаписатьАтрибут

Исключения

ЗаписатьАтрибутБайты

Исключения

ЗаписатьАтрибутБайтыBase64

Исключения

ЗаписатьАтрибутБулево

Исключения

ЗаписатьАтрибутВремя

Исключения

ЗаписатьАтрибутДата

Исключения

ЗаписатьАтрибутДатаВремя

Исключения

ЗаписатьАтрибутДлительность

Исключения

ЗаписатьАтрибутМомент

Исключения

ЗаписатьАтрибутМомент

Исключения

ЗаписатьАтрибутУуид

Исключения

ЗаписатьАтрибутЧисло

Исключения

ЗаписатьБайты

Исключения

ЗаписатьБайтыBase64

Исключения

ЗаписатьБезОбработки

Исключения

ЗаписатьБулево

Исключения

ЗаписатьВремя

Исключения

ЗаписатьДатаВремя

Исключения

ЗаписатьДату

ЗаписатьДлительность

Исключения

ЗаписатьИнструкциюОбработки

Исключения

ЗаписатьКомментарий

Исключения

ЗаписатьКонецДокумента

Исключения

ЗаписатьКонецЭлемента

Исключения

ЗаписатьМомент

Исключения

ЗаписатьНачалоДокумента

Исключения

ЗаписатьНачалоЭлемента

Исключения

ЗаписатьСекциюCData

Исключения

ЗаписатьСоответствиеПространстваИмен

Исключения

ЗаписатьСсылкуНаСущность

Исключения

ЗаписатьТекст

Исключения

ЗаписатьТипДокумента

Исключения

ЗаписатьУуид

Исключения

ЗаписатьЧисло

Исключения

Список унаследованных методов

Объект