Перейти к основному содержимому

Сценарии работы с приложениями системы взаимодействия

Создание нового приложения​

Перед созданием нового приложения вам необходимо получить код активации.

Для создания нового приложения используйте метод УправлениеПриложениямиВзаимодействия.СоздатьПриложениеВзаимодействия(). Укажите следующие параметры:

  • КлючиПриложенияВзаимодействия

    Экземпляр типа КлючиПриложенияВзаимодействия, который хранит открытый и закрытый ключ создаваемого приложения.

    Ключи могут быть сгенерированы «1С:Предприятие.Элементом Скриптом» автоматически при конструировании экземпляра типа КлючиПриложенияВзаимодействия:

    метод СоздатьКлючАвтоматически()
        пер Ключи = новый КлючиПриложенияВзаимодействия()
    ;

    Также вы можете генерировать ключи внешними утилитами, например keytool.

    Можно создать экземпляр КлючиПриложенияВзаимодействия с передачей в параметры конструктора ключей шифрования:

    метод СоздатьКлючи(ОткрытыйКлюч: Байты, ЗакрытыйКлюч: Байты)
        пер Ключи = новый КлючиПриложенияВзаимодействия(ОткрытыйКлюч, ЗакрытыйКлюч)
        // ...
    ;

    Здесь ОткрытыйКлюч и ЗакрытыйКлюч — это пара ключей в формате:

    • массива байтов;
    • строк в формате Base64.

  • ИдПользователяПриложения

    Ууид. Идентификатор пользователя приложения.

  • ИмяПользователяПриложения

    Строка. Краткое имя пользователя приложения.

  • ПолноеИмяПользователяПриложения

    Строка. Полное имя пользователя приложения.

  • КодАктивации

    Заранее полученный от сервера системы взаимодействия код для регистрации приложения.

  • ПочтаАбонента

    Адрес электронной почты пользователя, создающего приложение.

  • ИмяПриложения

    Имя приложения.

  • Сервер

    Адрес сервера взаимодействия.

  • ПараметрыСоединения

    Параметры защищенного соединения.

  • Таймаут

    Предельное время выполнения запроса к системе взаимодействия.

После вызова метода УправлениеПриложениямиВзаимодействия.СоздатьПриложениеВзаимодействия() сервер системы взаимодействия вернет набор реквизитов зарегистрированного приложения в экземпляре типа ПараметрыПриложенияВзаимодействия. Их нужно сохранить для дальнейшего использования:

Все параметры можно сохранить как строки любым доступным способом (в зависимости от дальнейшего использования).

После создания приложения и перед выполнением метода СистемаВзаимодействия.Войти() нужно вызвать метод СистемаВзаимодействия.Отключиться(), чтобы отсоединиться от системы взаимодействия. Если не выполнить этого шага, сервер системы взаимодействия будет возвращать ошибку «пользователь уже авторизован».

Подключение к системе взаимодействия и проверка сертификатов​

Проверка сертификатов при подключении к серверу системы взаимодействия​

При соединении с сервером системы взаимодействия с помощью метода СистемаВзаимодействия.Подключиться() «1С:Предприятие.Элемент Скрипт» проверяет сертификаты. Если проверка сертификата заканчивается неудачей, то выбрасывается исключение ИсключениеСистемыВзаимодействия.

В целях отладки приложения можно воспользоваться более простым методом СистемаВзаимодействия.ПодключитьсяБезПроверкиСертификата(), но мы не рекомендуем пользоваться этим методом в реальных приложениях.

метод ПроверитьСертификатИСоздатьПриложение()
    знч КодАктивации: Строка = "417929"
    знч АдресЭлектроннойПочты: Строка = "ivanov@company.com"
    знч ИмяПриложения: Строка = "ИмяПриложения"
    знч ИдентификаторПользователя: Ууид = Ууид{84eb3ebb-95ae-4dea-a025-adfa8961703c}
    знч ИмяПользователя: Строка = "Иван"
    знч ПолноеИмяПользователя: Строка = "Иванов Иван"
    
    знч Ключи: КлючиПриложенияВзаимодействия = новый КлючиПриложенияВзаимодействия()
    
    // Создание приложения и получение его параметров
    знч ПараметрыПриложенияСВ =
    УправлениеПриложениямиВзаимодействия.СоздатьПриложениеВзаимодействия(Ключи, ИдентификаторПользователя, 
                                            ИмяПользователя, ПолноеИмяПользователя, 
                                            КодАктивации, АдресЭлектроннойПочты, 
                                            ИмяПриложения)  
    
    // Подключение к системе взаимодействия.
    // В данном примере используется публичный сервис «1С:Диалог».
    СистемаВзаимодействия.Подключиться("wss://1cdialog.com:443", 
                                    "C:\\keystore.jks", 
                                    "keystorePassword", 
                                    "certPassword")
    
    // Работа с системой взаимодействия.
    // ...
    
    // Отключение от системы взаимодействия.
    СистемаВзаимодействия.Отключиться()
;

Проверка сертификатов через хранилище сертификатов Java​

Для упрощения работы можно подключаться к серверу системы взаимодействия без указания параметров ФайлХранилища, ПарольХранилища и ПарольКлюча в методе СистемаВзаимодействия.Подключиться(). Это возможно в том случае, если сертификат, используемый на сервере системы взаимодействия, подписан (выдан) доверенным удостоверяющим центром. Тогда выполняется встроенная проверка сертификата сервера с использованием входящих в его поставку JRE-сертификатов.

Если проверку сертификата, используемого на сервере, нельзя провести с использованием встроенных в Java сертификатов, вызов завершится исключением, а для успешного подключения необходимо будет указать параметры хранилища.

:::note title="Поддерживаемые форматы файлов сертификатов"

В параметре ФайлХранилища метода СистемаВзаимодействия.Подключиться() вы можете указывать путь к сертификату сервера взаимодействия форматов PKCS12 и JKS. :::

Объединение приложений взаимодействия​

Объединение приложений позволяет пользователям этих приложений вести переписку между собой.

метод ОбъединитьПриложенияВзаимодействия()
    знч ТекущееПриложение = СистемаВзаимодействия.ПолучитьТекущееПриложение()
    знч ИдВторогоПриложения = Ууид{6c79fc60-2373-11ed-861d-0242ac120002}
    знч ОбъединениеПриложений = новый ОбъединениеПриложенийВзаимодействия(ТекущееПриложение.Ид, ИдВторогоПриложения,
    РежимСопоставленияПользователейВзаимодействия.ПоПолномуИмени)
    СистемаВзаимодействия.ОбъединитьПриложения(ОбъединениеПриложений)
;

Отмена всех объединений приложений взаимодействия у абонента​

метод ОтменитьОбъединение()
    знч ОбъединенияПриложений = СистемаВзаимодействия.ПолучитьОбъединенияПриложений()
    для Объединение из ОбъединенияПриложений
        СистемаВзаимодействия.ОтменитьОбъединениеПриложений(Объединение.ИдПриложения, Объединение.ИдПарногоПриложения)
    ;
;

Получение необъединенных приложений взаимодействия​

метод ПолучитьНеобъединенныеПриложения()
    знч СписокПриложений = СистемаВзаимодействия.ПолучитьПриложенияАбонента()
    знч ОбъединенияПриложений = СистемаВзаимодействия.ПолучитьОбъединенияПриложений()

    пер ПриложенияБезОбъединения = новый Массив<ПриложениеВзаимодействия>()

    для Приложение из СписокПриложений
        пер ОбъединениеНайдено = Ложь
        для Объединение из ОбъединенияПриложений
            если Приложение.Ид != Объединение.ИдПриложения или Приложение.Ид != Объединение.ИдПарногоПриложения
                ОбъединениеНайдено = Истина
                прервать
            ;
        ;

        если не ОбъединениеНайдено
            ПриложенияБезОбъединения.Добавить(Приложение)
        ;
    ;
;
Последнее обновление