Статический метод

Статический метод — это метод, принадлежащий типу, а не его экземпляру.

Для вызова статического метода не нужно создавать экземпляр. Синтаксис вызова: имя-типа.имя-метода().

Например, вызов статического метода Текущий() у типа ЧасовойПояс выглядит следующим образом:

метод ПоказатьТекущийЧасовойПояс(): Строка
    // Вызов статического метода типа
    пер ТекущийЧасовойПояс = ЧасовойПояс.Текущий()
    возврат "Текущий часовой пояс: $ТекущийЧасовойПояс"
;

Системные статические методы в Стандартной библиотеке имеют обозначение Статический.

Вы также можете создавать статические методы у структур, перечислений и исключений. Для этого используйте ключевое слово статический. Пример статического метода структуры:

структура Прямоугольник
    обз знч Х: Число
    обз знч У: Число
    
    // Метод экземпляра — для вызова нужен экземпляр структуры
    метод Площадь(): Число
        возврат Х * У
    ;
    
    // Статический метод — можно использовать без создания экземпляра структуры
    статический метод Квадрат(Сторона: Число): Прямоугольник
        возврат новый Прямоугольник(Сторона, Сторона)
    ;
;

метод Скрипт(): Соответствие<Прямоугольник, Число>
    пер Соответствие = новый Соответствие<Прямоугольник, Число>()
    // Создание экземпляра через конструктор
    пер Фигура = новый Прямоугольник(1, 2)
    // Фигура.Площадь() — вызовет метод экземпляра структуры
    Соответствие.Вставить(Фигура, Фигура.Площадь())
    // Использование статического метода без создания экземпляра
    пер Квадрат = Прямоугольник.Квадрат(5)
    Соответствие.Вставить(Квадрат, Квадрат.Площадь())
    возврат Соответствие
;

См. также

• Методы
• Структура