Использование конструктора запроса

Создание запроса с помощью конструктора выглядит следующим образом:

пер Запрос = новый Запрос(
                           "ВЫБРАТЬ 
                              Сотрудники.Ссылка КАК Ссылка,
                              Сотрудники.ФИО КАК ФИО 
                           ИЗ
                              Сотрудники КАК Сотрудники")

При необходимости можно сначала создать запрос без текста, а затем установить свойство Текст:

пер Запрос = новый Запрос()
Запрос.Текст = 
               "ВЫБРАТЬ 
                  Сотрудники.Ссылка КАК Ссылка,
                  Сотрудники.ФИО КАК ФИО 
               ИЗ
                  Сотрудники КАК Сотрудники"

При использовании конструктора переменная Запрос имеет тип ПроизвольныйЗапрос.

Обход результата запроса

Для создания переменной, в которой будет храниться результат запроса, используйте модификатор исп. Он необходим для того, чтобы «1С:Шина» закрыл результат запроса после окончания работы с ним.

// Выполнить запрос.
исп РезультатЗапроса = Запрос.Выполнить()

Если вы передаете результат запроса в другие методы или модули, то там, при необходимости, вы можете самостоятельно закрыть его РезультатЗапроса.Закрыть().

После выполнения запроса результат запроса не спозиционирован ни на какой своей записи. Поэтому для того, чтобы получить значения первой записи, нужно выполнить метод РезультатЗапроса.Следующий().

Для обращения к полям результата запроса можно использовать их псевдонимы из текста запроса или, если их нет, псевдонимы, автоматически сформированные «1С:Шиной».

// Обойти результат запроса и обработать его.
пока РезультатЗапроса.Следующий()
   пер СотрудникСсылка = РезультатЗапроса.Ссылка    
   пер СотрудникФИО = РезультатЗапроса.ФИО
;

Если псевдонимы нужных вам полей определяются программным алгоритмом, то можно использовать либо операцию [], либо метод РезультатЗапроса.Получить().

// Обойти результат запроса и обработать его.
пер ПолеСсылки = "Ссылка"
пер ПолеФИО = "ФИО"
пока РезультатЗапроса.Следующий()
   пер СотрудникСсылка = РезультатЗапроса[ПолеСсылки]    
   пер СотрудникФИО = РезультатЗапроса.Получить(ПолеФИО)
;

Параметры запроса

Для установки параметров запроса используйте метод ПроизвольныйЗапрос.УстановитьПараметр().

// Установить значения параметров запроса.
Запрос.УстановитьПараметр("Возраст", 40)

При установке параметров запроса «1С:Шина» не выполняет никаких проверок. Можно установить значение параметра, которого нет в тексте запроса. Можно повторно установить значение параметра, тем самым «затерев» предыдущее значение.