Сценарии работы с приложениями системы взаимодействия

Получение кода активации и регистрация текущего приложения в 1С:Диалог

знч ПочтаАбонента = "admin@company.ru"

// получаем код активации на электронную почту, далее выполняем регистрацию
УправлениеПриложениямиВзаимодействия.ЗапроситьКодАктивации(ПочтаАбонента)

знч КодАктивации = "КодИзПочты"

СистемаВзаимодействия.ЗарегистрироватьПриложение(
                        ПочтаАбонента = ПочтаАбонента,
                        ИмяПриложения = "Приложение для торговли",
                        КодАктивации = КодАктивации)
         

Ручная установка данных регистрации в системе взаимодействия

Такой способ предназначен для миграции приложения или восстановления данных подключения из резервной копии.

// Сервер - 1С: Диалог

// Ранее известные данные
знч ОткрытыйКлюч = "QWERTYU4567=..."
знч ЗакрытыйКлюч = "QWERTYU4567=..."
знч КлючиПриложения = новый КлючиПриложенияВзаимодействия(ОткрытыйКлюч.ВБайты(), ЗакрытыйКлюч.ВБайты())

знч ДанныеРегистрации = новый ДанныеРегистрацииПриложенияВзаимодействия(
                                 ИдПриложения = Ууид{86669b56-32c9-49bb-9b5b-31cde9a79538},
                                 КлючиПриложения = КлючиПриложения,
                                 ОткрытыйКлючСервера = "QWERTYU4567=...")

// Установка данных регистрации должна выполняться под пользователем с правами администратора
СистемаВзаимодействия.УстановитьДанныеРегистрацииПриложения(ДанныеРегистрации)
         

// Произвольный сервер

// Ранее известные данные
знч ОткрытыйКлюч = "QWERTYU4567=..."
знч ЗакрытыйКлюч = "QWERTYU4567=..."
знч КлючиПриложения = новый КлючиПриложенияВзаимодействия(ОткрытыйКлюч.ВБайты(), ЗакрытыйКлюч.ВБайты())

знч ДанныеРегистрации = новый ДанныеРегистрацииПриложенияВзаимодействия(
                                 Сервер = "wss//my.ecs.server.ru?version=4",
                                 ИдПриложения = Ууид{86669b56-32c9-49bb-9b5b-31cde9a79538},  
                                 КлючиПриложения = КлючиПриложения,
                                 ОткрытыйКлючСервера = "QWERTYU4567=...")

// Установка данных регистрации должна выполняться под пользователем с правами администратора
СистемаВзаимодействия.УстановитьДанныеРегистрацииПриложения(ДанныеРегистрации)
         

Объединение приложений взаимодействия

Объединение приложений позволяет пользователям этих приложений вести переписку между собой.

знч ТекущееПриложение = СистемаВзаимодействия.ПолучитьТекущееПриложение()
знч ИдВторогоПриложения = Ууид{6c79fc60-2373-11ed-861d-0242ac120002}
знч ОбъединениеПриложений = новый ОбъединениеПриложенийВзаимодействия(ТекущееПриложение.Ид, ИдВторогоПриложения,
РежимСопоставленияПользователейВзаимодействия.ПоПолномуИмени)

СистемаВзаимодействия.ОбъединитьПриложения(ОбъединениеПриложений)
         

Отмена всех объединений приложений взаимодействия у абонента

знч ОбъединенияПриложений = СистемаВзаимодействия.ПолучитьОбъединенияПриложений()

для Объединение из ОбъединенияПриложений
   СистемаВзаимодействия.ОтменитьОбъединениеПриложений(Объединение.ИдПриложения, Объединение.ИдПарногоПриложения)
;
         

Получение необъединенных приложений взаимодействия

знч СписокПриложений = СистемаВзаимодействия.ПолучитьПриложенияАбонента()
знч ОбъединенияПриложений = СистемаВзаимодействия.ПолучитьОбъединенияПриложений()

пер ПриложенияБезОбъединения = новый Массив<ПриложениеВзаимодействия>()

для Приложение из СписокПриложений
   пер ОбъединениеНайдено = Ложь
   для Объединение из ОбъединенияПриложений
      если Приложение.Ид != Объединение.ИдПриложения или Приложение.Ид != Объединение.ИдПарногоПриложения
         ОбъединениеНайдено = Истина
         прервать
      ;
   ;
   
   если не ОбъединениеНайдено
      ПриложенияБезОбъединения.Добавить(Приложение)
   ;
;