Перейти к основному содержимому

{ИмяРегистраСведений}.СрезПоследних

Виртуальная таблица, которая возвращает последние внесённые в регистр сведений записи для каждой комбинации измерений.

Параметры:

  • Период: Дата?
    Граница, включая которую будет формироваться срез.

Срез будет формироваться на основе записей, у которых значение поля Период меньше или равно указанному значению параметра. При наличии нескольких записей с одинаковыми значениями измерений в результате будет использоваться запись с самым большим значением периода.

Если значение параметра Неопределено, возвращаются последние актуальные записи (с максимальным значением поля Период на текущий момент).

Примеры​

В примере ниже показано, как выбрать цены товаров из регистра Цены, актуальные на указанный ПараметрПериод (у которых значение поля Период меньше или равно переданному):

ВЫБРАТЬ
    Цены.Товар КАК Товар,
    Цены.Цена КАК Цена,
    Цены.Примечание КАК Примечание
ИЗ
    Цены.СрезПоследних(%ПараметрПериод) КАК Цены
УПОРЯДОЧИТЬ ПО
    Товар,
    Цена

Поля​

{ИмяИзмерения}​

Ключевое поле

{ИмяИзмерения}: ТипИзмерения

Значение измерения записи регистра сведений.

{ИмяРесурса}​

{ИмяРесурса}: ТипРесурса

Значение ресурса записи регистра сведений.

{ИмяРеквизита}​

{ИмяРеквизита}: ТипРеквизита

Значение реквизита записи регистра сведений.

Период​

Ключевое поле

Период: Дата

Период, к которому относится запись регистра. Присутствует только у периодических регистров сведений.

СледующийПериод​

Вычисляемое поле

СледующийПериод: Дата

Имеет значение поля Период из следующей записи с такими же значениями измерений или максимальное значение типа поля Период, если следующей записи нет. Присутствует только у периодических регистров сведений.

Примеры​

В примере ниже показано, как получить актуальный курс валюты из регистра сведений Курсы на указанную дату %ДатаСреза (используя виртуальную таблицу СрезПоследних) и определить период действия этого курса:

знч Запрос = Запрос{
        ВЫБРАТЬ
            Период,
            Курс,
            Валюта,
        ИЗ
            Курсы.СрезПоследних(%ДатаСреза)
        }

знч Результат = Запрос.Выполнить().Единственный()
пер СледующийПериод = Результат.СледующийПериод

Для того чтобы проверить наличие следующей записи в таблице периодического регистра сведений, можно сравнить значение поля СледующийПериод с максимальным значением типа поля Период. Если они равны — значит следующей записи не существует.

Получить максимальное значение типа поля Период можно с помощью встроенного строкового литерала соответствующего типа: Тип{Максимум} (как в запросе выше).

КлючОсновногоФильтра​

Вычисляемое поле

КлючОсновногоФильтра: ИмяРегистраСведений.КлючОсновногоФильтра

Структура, описывающая ключ основного фильтра регистра сведений. Добавляется даже если нет измерений, включаемых в основной фильтр. Имеет тип имя-регистра-сведений.КлючОсновногоФильтра.

КлючЗаписи​

Вычисляемое поле

КлючЗаписи: ИмяРегистраСведений.КлючЗаписи

Содержит значения измерений записи регистра сведений (и стандартного поля Период для периодических регистров сведений). Используется для указания на конкретную запись. Имеет тип имя-регистра-сведений.КлючЗаписи.

Примеры​

В примере ниже показано, как выбрать данные конкретной записи из виртуальной таблицы Курсы.СрезПоследних на указанную дату %ДатаСреза по её ключу (значение поля КлючЗаписи равно параметру %КлючКурсаРубля):

ВЫБРАТЬ
    Период,
    Курс,
    Валюта,
    СледующийПериод
ИЗ
    Курсы.СрезПоследних(%ДатаСреза)
ГДЕ
    КлючЗаписи == %КлючКурсаРубля
Последнее обновление