метод ЗаписатьСШифрованием(ФайлДляСжатия: Файл)
    // Создание объект взаимодействия с архивом
    // Благодаря паролю можно распаковывать файлы (если архив уже существует и файлы зашифрованы) и добавлять новые в зашифрованном виде МетодШифрованияПоУмолчанию = МетодШифрованияZip.Zip20
    пер Архив = новый ФайлZip(Файлы.ПолучитьДомашнийКаталог().Путь + "/archive.zip", "password")
 
    // Для новых файлов установим максимальный уровень сжатия, иначе значение будет Нормальный
    пер УровеньСжатияПоУмолчанию = УровеньСжатияZip.Максимальный
    
    // Для новых файлов установим метод шифрования, иначе значение будет Zip20 (так как открыли архив с паролем)
    пер МетодШифрованияПоУмолчанию = МетодШифрованияZip.Aes256
     
    // Добавим каталог с файлами
    Архив.Добавить(Файлы.ПолучитьДомашнийКаталог().Путь + "/КаталогСФайламиДляСжатия", "", УровеньСжатияПоУмолчанию, МетодШифрованияПоУмолчанию)
 
    // Добавим в корень файл
    Архив.Добавить(ФайлДляСжатия, "", УровеньСжатияПоУмолчанию, МетодШифрованияПоУмолчанию)
    
    // Можем добавить через поток
    Архив.Добавить(ФайлДляСжатия.ОткрытьПотокЧтения(), "КаталогСФайламиДляСжатия/ФайлДляСжатия_Копия", УровеньСжатияПоУмолчанию, Момент.Сейчас(), МетодШифрованияПоУмолчанию)
    Архив.УстановитьКомментарий("Архив с КаталогСФайламиДляСжатия и файлом. Сделана копия. Пароль: password")
     
    // Закрывать Архив или сохранять изменения не нужно, данные команды выполняются автоматически после каждого вызова метода объекта Архив
;

метод СоздатьФайлАрхиваИДобавитьФайл(ИмяФайла: Строка, Пароль: Строка, ФайлДляСжатия: Файл): ФайлZip
    // Создание объекта нового файла архива с именем ИмяФайла в домашнем каталоге и паролем Пароль
    пер Архив = новый ФайлZip(Файлы.ПолучитьДомашнийКаталог().Путь + "/" + ИмяФайла, Пароль)
    
    попытка
        Архив.Добавить(Источник = ФайлДляСжатия)
    поймать И: Исключение
        // обработка исключения в случае, если файл с переданным именем уже существует и не является валидным архивом zip 
    ;
    
    возврат Архив
;

метод ДобавитьФайлВАрхив(ФайлДляСжатия: Файл, Архив: ФайлZip)
    // Добавление файла в архив с нормальным уровнем сжатия
    Архив.Добавить(Источник = ФайлДляСжатия, УровеньСжатия = УровеньСжатияZip.Нормальный)
;

метод ДобавитьФайлВАрхив(ФайлДляСжатияПоток: ПотокЧтения, Архив: ФайлZip, ФайлПутьВАрхиве: Строка)
    // Добавление файла через поток чтения в архив с максимальным уровнем сжатия, путь передается в параметре ПутьВАрхиве, например, "КаталогСФайламиДляСжатия/ИмяФайла.txt"
    Архив.Добавить(Источник = ФайлДляСжатияПоток, ПутьВАрхиве = ФайлПутьВАрхиве, УровеньСжатия = УровеньСжатияZip.Максимальный)
;

метод УдалитьЗашифрованныеФайлыВАрхиве(Архив: ФайлZip)
    // Удаление всех зашифрованных файлов в архиве
    если Архив.ЕстьЗашифрованныеФайлы()
        Архив.Элементы()
            .Фильтровать(Элемент -> не Элемент.ЭтоКаталог() и Элемент.Зашифрован())
            .ДляКаждого(Элемент -> Архив.Удалить(Элемент))
    ;
;

метод ИзвлечьФайлИзАрхива(Архив: ФайлZip, ФайлПутьВАрхиве: Строка, КаталогРаспаковки: Строка)
    // Распаковка файла в каталог, например, "КаталогСФайламиДляСжатия/ИмяФайла.txt" в "КаталогРаспаковки" домашнего каталога
    Архив.Извлечь(ФайлПутьВАрхиве, Файлы.ПолучитьДомашнийКаталог().Путь + "/" + КаталогРаспаковки)
;

метод ИзвлечьФайлыПоРасширениюИзАрхива(Архив: ФайлZip, РасширениеФайла: Строка, КаталогРаспаковки: Строка)
    // Распаковка элементов архива с расширением РасширениеФайла, измененных за последние сутки,
    // в домашний каталог КаталогРаспаковки и подкаталог РасширениеФайла,
    // например, файлы с расширением "pdf",  в каталог "КаталогРаспаковки/pdf"
    для Элемент из Архив.Элементы()
        если Элемент.Расширение == РасширениеФайла и Элемент.ВремяИзменения >= Момент.Сейчас() - 1д
            Архив.Извлечь(Элемент, новый Файл(Файлы.ПолучитьДомашнийКаталог().Путь, [КаталогРаспаковки, РасширениеФайла]))
        ;
    ;
;

// Исходная структура архива, имена файлов отличаются (1)
// a/test1.txt
// b/test2.txt
// c/test3.txt
// c/a/test4.txt

// Исходная структура архива, имена файлов совпадают (2)
// a/test.txt
// b/test.txt
// c/test.txt
// c/a/test.txt

метод ИзвлечьВсеСКаталогами(Архив: ФайлZip, КаталогНазначения: Строка)
    // Распаковка всех элементов архива в каталог КаталогНазначения, с восстановлением структуры каталогов из архива
    Архив.ИзвлечьВсе(КаталогНазначения)

    // Результат (1)
    // a/test1.txt
    // b/test2.txt
    // c/test3.txt
    // c/a/test4.txt
    
    // Результат (2)
    // a/test.txt
    // b/test.txt
    // c/test.txt
    // c/a/test.txt
;

метод ИзвлечьВсеБезКаталогов(Архив: ФайлZip, КаталогНазначения: Строка)
    // Распаковка всех элементов архива в каталог КаталогНазначения, без восстановления структуры каталогов из архива
    Архив.ИзвлечьВсе(КаталогНазначения, Ложь)
    
    // Результат (1)
    // test1.txt
    // test2.txt
    // test3.txt
    // test4.txt
    
    // Результат (2)
    // test.txt (из каталога c/a/)
;

метод НайтиИПереписатьФайл(ПутьКАрхиву: Строка, ИмяФайла: Строка, НовыеДанные: ПотокЧтения)
    пер Архив = новый ФайлZip(ПутьКАрхиву)
 
    // Поиск файла - точный путь к файлу в архиве неизвестен, но известно имя файла
    пер Элементы = Архив.Найти(ИмяФайла)
    если Элементы.Размер() != 1
        выбросить новый ИсключениеНедопустимыйАргумент()
    ;
 
    пер ИскомыйЭлемент = Элементы.Получить(0)
     
    // Замена файла
    Архив.Удалить(ИскомыйЭлемент)
    Архив.Добавить(НовыеДанные, ИскомыйЭлемент.ПутьВАрхиве, УровеньСжатияZip.Максимальный)
;

метод УдалитьФайлВАрхиве(Архив: ФайлZip, ФайлПутьВАрхиве: Строка)
    // Удаление файла в архиве по его пути ФайлПутьВАрхиве, например, "КаталогСФайламиДляСжатия/ИмяФайла.txt"
    Архив.Удалить(ФайлПутьВАрхиве)
;

метод УдалитьКаталогВАрхиве(Архив: ФайлZip, КаталогПутьВАрхиве: Строка)
    // Удаление каталога и его содержимого в архиве по его пути КаталогПутьВАрхиве, например, "КаталогСФайламиДляСжатия"
    Архив.Удалить(КаталогПутьВАрхиве)
;

метод ВычислитьРазмерНесжатогоВАрхиве(Архив: ФайлZip): РазмерБайтов
    // Вычисление общего размера несжатых файлов в архиве
    пер ОбщийРазмерБайтов = 0б
    для Элемент из Архив.Элементы()
        ОбщийРазмерБайтов += Элемент.РазмерНесжатого
    ;
    возврат ОбщийРазмерБайтов
;

метод ВычислитьРазмерСжатогоВАрхиве(Архив: ФайлZip, Каталог: Строка): РазмерБайтов
    // Вычисление общего размера сжатых файлов в каталоге архива, например, "КаталогСФайламиДляСжатия"
    пер ОбщийРазмерБайтов = 0б
    для Элемент из Архив.Элементы()
        если Элемент.ПутьВАрхиве.Содержит(Каталог, Истина)
            ОбщийРазмерБайтов += Элемент.РазмерСжатого
        ;
    ;
    возврат ОбщийРазмерБайтов
;