Настройка информационной базы «1С:Предприятие»

Сейчас вы выполняете третий этап. По условию примера, менеджер «Книжного дома» отправляет прайс-листы из базы «1С:Предприятия» в «1С:Шину» по протоколу AMQP. В данном примере отправка прайс-листа будет осуществляться посредством встроенной обработки, а сам XML-текст с прайс-листом для простоты проверки обмена сообщениями уже записан в коде. Модуль, который отвечает за формирование и отправку сообщения, вы можете найти, открыв конфигурацию демонстрационной базы в «1С:EDT». Он располагается во вкладке Обработки > ОтправкаПрайсЛиста > Формы > Форма > Модуль и выглядит следующим образом:

&НаКлиенте
Процедура ОтправитьПрайсЛист(Команда)
	КодПолучателя = ПолучитьКод(Получатель);
	ОтправитьСообщениеНаСервере(КодПолучателя);
КонецПроцедуры


&НаСервере
Процедура ОтправитьСообщениеНаСервере(КодПолучателя)
	Содержимое = 
    "<items>
	|	<item id=""1"">
    |		<name>Война и мир</name>
    |    	<author>Лев Толстой</author>
    |    	<year>2022</year>
    |    	<price>550</price>
    |    	<retail>770</retail>
    |    	<currency>RUB</currency>
    | 	</item>
    | 	<item id=""2"">
    |    	<name>1984</name>
    |    	<author>Джордж Оруэлл</author>
    |    	<year>2020</year>
    |    	<price>350</price>
    |    	<retail>540</retail>
    |    	<currency>RUB</currency>
    |	</item>
    |	<item id=""3"">
    |    	<name>Обломов</name>
    |    	<author>Иван Гончаров</author>
    |    	<year>2022</year>
    |    	<price>600</price>
    |    	<retail>800</retail>
    |   	<currency>RUB</currency>
    |	</item>
    |</items>";
    
	Сообщение = СервисыИнтеграции.СервисБазы.СоздатьСообщение();
	Сообщение.КодПолучателя = КодПолучателя;
	Тело = Сообщение.ПолучитьТелоКакПоток();
	Буфер = ПолучитьБуферДвоичныхДанныхИзСтроки(Содержимое);
	Тело.Записать(Буфер, 0, Буфер.Размер);
	Тело.Закрыть();
	СервисыИнтеграции.СервисБазы.ИзБазы.ОтправитьСообщение(Сообщение);
КонецПроцедуры


&НаСервереБезКонтекста
Функция ПолучитьКод(Получатель)
	Возврат Получатель.Код;
КонецФункции